Как нарисовать пружину (спираль)?

https://www.caduser.ru/forum/search.htm … 0%E0%EB%FC

можно половинками тора...это уже обсуждалось...выкручивания на обычной спирали быть не может, поэтому просто половинками, поднимая их на нужный угол...

Тут есть необходимые программки с подробным описанием
http://cadburg.by.ru/articles/ac_circramp/ramp-art.htm

скачав 3dSpiral.lsp, в AutoCAD`e нажимаете:
"Tools > Load Application...", находите тот самый файл и вуаля. готово !
Затем в коммандной строке пишите "3dspiral" или "spiral" в зависимости оттого какая вам нужна спираль на плоскости (2d) или в 3d.

Всё сделал. Только как строить спираль, там много опций?

> Teodor_2000
линия является путём (Path) для Еxtrudа какого либо shape (формы) - это может быть ваш круг, квадрат или любая замкнутая полилиния.

> scj
К сожалению там файл удален... (
а m2s.lsp ? это что ? тоже спираль ?

@Essef и Oleg(jr.)
получили ли Вы мой личный email?
С приветом
Jochen
www.black-cad.de

> Евгений
Выкладываю все по просьбе Йохена:
;;;   SPIRAL.LSP
;;;   Copyright (C) 1992 by Autodesk, Inc.
;;;
;;;   Permission to use, copy, modify, and distribute this software
;;;   for any purpose and without fee is hereby granted, provided
;;;   that the above copyright notice appears in all copies and that
;;;   both that copyright notice and this permission notice appear in
;;;   all supporting documentation.
;;;
;;;   THIS SOFTWARE IS PROVIDED "AS IS" WITHOUT EXPRESS OR IMPLIED
;;;   WARRANTY.  ALL IMPLIED WARRANTIES OF FITNESS FOR ANY PARTICULAR
;;;   PURPOSE AND OF MERCHANTABILITY ARE HEREBY DISCLAIMED.
;;; --------------------------------------------------------------------------;
;;; DESCRIPTION
;;;
;;;   This is a programming example.
;;;
;;;   Designed and implemented by Kelvin R. Throop in January 1985
;;;
;;;   This program constructs a spiral. It can be loaded and called
;;;   by typing either "spiral", "3dspiral" or the following:
;;;   (cspiral <# rotations> <base point> <horiz growth per rotation>
;;;            <points per circle> <start radius>
;;;            <vert growth per rotation>).
;;;
;;; --------------------------------------------------------------------------;
(defun myerror (s)                    ; If an error (such as CTRL-C) occurs
                                      ; while this command is active...
  (if (/= s "Function cancelled")
    (princ (strcat "\nError: " s))
  )
  (setvar "cmdecho" ocmd)             ; Restore saved modes
  (setvar "blipmode" oblp)
  (setq *error* olderr)               ; Restore old *error* handler
  (princ)
)
(defun cspiral (ntimes bpoint hfac lppass strad vfac
                / ang dist tp ainc dhinc dvinc circle dv)
  (setvar "blipmode" 0)               ; turn blipmode off
  (setvar "cmdecho" 0)                ; turn cmdecho off
  (setq circle (* 3.141596235 2))
  (setq ainc (/ circle lppass))
  (setq dhinc (/ hfac lppass))
  (if vfac (setq dvinc (/ vfac lppass)))
  (setq ang 0.0)
  (if vfac
    (setq dist strad dv 0.0)
    (setq dist 0.0)
  )
  (if vfac
    (command "3dpoly")                ; start spiral ...
    (command "pline" bpoint)          ; start spiral from base point and...
  )
  (repeat ntimes
    (repeat lppass
      (setq tp (polar bpoint (setq ang (+ ang ainc))
                      (setq dist (+ dist dhinc))
               )
      )
      (if vfac
          (setq tp (list (car tp) (cadr tp) (+ dv (caddr tp)))
                dv (+ dv dvinc)
          )
      )
      (command tp)                    ; continue to the next point...
    )
  )
  (command "")                        ; until done.
  (princ)
)
;;;
;;;       Interactive spiral generation
;;;
(defun C:SPIRAL (/ olderr ocmd oblp nt bp cf lp)
  (setq olderr  *error*
        *error* myerror)
  (setq ocmd (getvar "cmdecho"))
  (setq oblp (getvar "blipmode"))
  (setvar "cmdecho" 0)
  (initget 1)                         ; bp must not be null
  (setq bp (getpoint "\nCenter point: "))
  (initget 7)                         ; nt must not be zero, neg, or null
  (setq nt (getint "\nNumber of rotations: "))
  (initget 3)                         ; cf must not be zero, or null
  (setq cf (getdist "\nGrowth per rotation: "))
  (initget 6)                         ; lp must not be zero or neg
  (setq lp (getint "\nPoints per rotation <30>: "))
  (cond ((null lp) (setq lp 30)))
  (cspiral nt bp cf lp nil nil)
  (setvar "cmdecho" ocmd)
  (setvar "blipmode" oblp)
  (setq *error* olderr)               ; Restore old *error* handler
  (princ)
)
;;;
;;;       Interactive spiral generation
;;;
(defun C:3DSPIRAL (/ olderr ocmd oblp nt bp hg vg sr lp)
  (setq olderr  *error*
        *error* myerror)
  (setq ocmd (getvar "cmdecho"))
  (setq oblp (getvar "blipmode"))
  (setvar "cmdecho" 0)
  (initget 1)                         ; bp must not be null
  (setq bp (getpoint "\nCenter point: "))
  (initget 7)                         ; nt must not be zero, neg, or null
  (setq nt (getint "\nNumber of rotations: "))
  (initget 7)                         ; sr must not be zero, neg, or null
  (setq sr (getdist bp "\nStarting radius: "))
  (initget 1)                         ; cf must not be zero, or null
  (setq hg (getdist "\nHorizontal growth per rotation: "))
  (initget 3)                         ; cf must not be zero, or null
  (setq vg (getdist "\nVertical growth per rotation: "))
  (initget 6)                         ; lp must not be zero or neg
  (setq lp (getint "\nPoints per rotation <30>: "))
  (cond ((null lp) (setq lp 30)))
  (cspiral nt bp hg lp sr vg)
  (setvar "cmdecho" ocmd)
  (setvar "blipmode" oblp)
  (setq *error* olderr)               ; Restore old *error* handler
  (princ)
)
;;; --------------------------------------------------------------------------;
(princ "\n\tC:SPIRAL and C:3DSPIRAL loaded. ")
(princ)

> Евгений
А это вариант пружины постоянного диаметра, правда не очень гладкой,
если устроит, переделай для интерактивного ввода парметров самммммммм
(defun C:SPE (/ *error      *error*     acapp adoc  an    ang   h
          ht    hz      l    mdsp  n        ocmd  older    oosm  p0
          pts1  pts2  rad    s1    s2    s3      s4    s5    s6
          s7    solid ss    ss2   surf1 surf2 tmp1    tmp2  ts
          vs
         )
  (vl-load-com)
  (setq ocmd (getvar "cmdecho"))
  (setvar "cmdecho" 0)
  (setq oosm (getvar "osmode"))
  (setvar "osmode" 0)
  (setq surf1 (getvar "surftab1"))
  (setvar "surftab1" 64)
  (setq surf2 (getvar "surftab2"))
  (setvar "surftab2" 64)
  (or acapp (setq acapp (vlax-get-acad-object)))
  (or adoc (setq adoc (vla-get-activedocument acapp)))
  (or mdsp (setq mdsp (vla-get-modelspace adoc)))
  (defun *error    (msg)
    (vla-endundomark adoc)
    (command "_.U")
    (princ "\nОтмена рисования спирали\n")
    (princ)
  )
  (alert "\nДлительное выполнение")
  (vla-startundomark adoc)
  (setq    older    *error*
    *error*    *error
  )
  (vl-cmdf "plan" "w")
  (setq    l   120.                  ;высота пружины
    rad 100.                  ;внутренний диаметр пружины
    h   40.                      ; шаг пружины
    vs  10.                      ;ширина витка
    ts  5.                      ; толщина витка
    n   32                      ; число сегментов на виток
    hz  (/ h n)                  ; приращение по высоте на один сегмент
    p0  '(0. 0. 0.)
    ang (* (/ pi n) 2)
    an  0
  )
  (setq    an 0
    ht 0.
  )
  (repeat (fix (/ l h))
    (repeat (1+ n)
      (setq tmp1 (polar p0 an rad))
      (setq pts1 (cons (list (car tmp1) (cadr tmp1) ht) pts1))
      (setq ht (+ ht hz))
      (setq an (+ an ang))
    )
  )
  (setq    an  0
    ht  0.
    rad (+ vs rad)
  )
  (repeat (fix (/ l h))
    (repeat (1+ n)
      (setq tmp2 (polar p0 an rad))
      (setq pts2 (cons (list (car tmp2) (cadr tmp2) ht) pts2))
      (setq ht (+ ht hz))
      (setq an (+ an ang))
    )
  )
  (setq    pts1 (reverse pts1)
    pts2 (reverse pts2)
  )
  (setq    ss  (ssadd)
    ss2 (ssadd)
  )
  (while (caddr pts1)
    (setq ss (ssadd))
    (command "line" (car pts1) (car pts2) "")
    (ssadd (entlast) ss)
    (command "line" (caddr pts1) (caddr pts2) "")
    (ssadd (entlast) ss)
    (command "arc" (car pts1) (cadr pts1) (caddr pts1))
    (ssadd (entlast) ss)
    (command "arc" (car pts2) (cadr pts2) (caddr pts2))
    (ssadd (entlast) ss)
    (command "pedit" "m" ss "" "y" "j" "" "")
    (command "extrude" (entlast) "" (* ts 4) "")
    (setq solid (entlast))
    (setvar "osmode" 0)
    (command "osnap" "non")
    (setq
      s1 (car pts2)
      s2 (caddr pts2)
      s3 (inters (cadr pts2) (cadr pts1) (list 0. 0. l) p0 nil)
      s4 (list (car s1) (cadr s1) (+ (caddr s1) ts))
      s5 (list (car s2) (cadr s2) (+ (caddr s2) ts))
      s6 (list (car s3) (cadr s3) (+ (caddr s3) ts))
      s7 (list (car s1) (cadr s1) (+ (caddr s1) (* ts 3)))
    )
    (command "slice" solid "" "" s1 s2 s3 s7)
    (command "slice" solid "" "" s4 s5 s6 s1)
    (ssadd (entlast) ss2)
    (setq pts1 (cddr pts1)
      pts2 (cddr pts2)
    )
    (setq ss nil)
  )
  (command "union" ss2 "")
  (vl-cmdf "-view" "swiso")
  (vla-zoomextents (vla-get-application adoc))
  (vla-regen adoc acactiveviewport)
  (setvar "surftab1" surf1)
  (setvar "surftab2" surf2)
  (setvar "osmode" oosm)
  (setvar "cmdecho" ocmd)
  (setq    *error*    older
    *error nil
  )
(gc)
  (vla-endundomark adoc)
(princ)
)
;;;  TesT:(C:SPE)
~'O'~