Подсчет количества блоков в чертеже (Страница 1 из 3)

(defun c:bcount (/ curEnt dxfList blName Count)
  (if
  (setq curEnt(entsel "*** Select sample block "))
  (progn
   (setq dxfList(entget(car curEnt)))
  (terpri)
  (if(= "INSERT"(cdr(assoc 0 dxfList)))
    (progn
    (setq blName(cdr(assoc 2 dxfList))
          Count(sslength(ssget "_X"
        (list(assoc 2 dxfList))))
      ); end setq
    (princ(strcat "*** Block name: " blName
          "\n*** Blocks in drawing: "(itoa Count)))
    );end progn
    (princ "\n*** This don't block!\n ")
    ); end if
  ); end progn
  (princ "\n*** Nothing selected!\n ")
  ); end if
  (princ)
  ); end bstat

(defun block_number (/ ss bname)
  (princ "\nБлоки - Вхождения\n")
  (vlax-for block (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
    (setq bname (vla-get-name block))
    (if (wcmatch bname "~*Space*")
      (princ (strcat bname
                     " - "
                     (if (setq ss (ssget "_X" (list '(0 . "insert") (cons 2 bname) '(410 . "Model"))))
                       (rtos (sslength ss) 2 0)
                       "0"
                     ) ;_  if
                     "\n"
             ) ;_  strcat
      ) ;_  princ
    ) ;_  if
  ) ;_  vlax-for
  (princ)
) ;_  defun
(block_number) ;_ автозапуск

(defun C:BLCOUNT ( / FILEPATH FILE_NAME INSLIST INSNAMES INSS LEN OUTPUT)
  (if (setq INSS (ssget '((0 . "INSERT"))))
    (progn
      (setq INSLIST (vl-remove-if-not 'atom (mapcar 'cadr (ssnamex (ssget '((0 . "INSERT")))))))
      (setq INSNAMES (vl-sort (mapcar '(lambda (X) (cdr (assoc 2 (entget X)))) INSLIST) '<))
      (setq LEN (length INSNAMES))
      (while INSNAMES
    (setq OUTPUT (cons (cons
                 (car INSNAMES)
                 (- LEN (setq LEN (length (setq INSNAMES (vl-remove (car INSNAMES) INSNAMES))))))
               OUTPUT)
          ) ;_ end of setq
    ) ;_ end of while
      (setq OUTPUT (reverse OUTPUT))
      (if (setq    FILEPATH (getfiled "Save Text File As"
                   (strcat (getvar "dwgprefix")
                       (substr (getvar "dwgname") 1 (- (strlen (getvar "dwgname")) 4)) ".txt")
                   "txt"
                   33
                   ) ;_ end of getfiled
        ) ;_ end of setq
    (if (setq FILE_NAME (open FILEPATH "w"))
      (progn
        (mapcar '(lambda (X) (write-line (strcat (car X) " " (itoa (cdr X))) FILE_NAME)) OUTPUT)
        (close FILE_NAME)
        (startapp "NOTEPAD" FILEPATH)
        ) ;_ end of progn
      (vlax-invoke-method (vlax-get-or-create-object "WScript.Shell") "Popup"
        (strcat "File: [" FILEPATH "] is busy!") 0 "Warning" 16)
      ) ;_ end of if
    ) ;_ end of if
      ) ;_ end of progn
    ) ;_ end of if
  (princ)
  ) ;_ end of defun