Txtout

;*************************************************************************
;                            WTEXT.LSP
;   By Simon Jones      Autodesk Ltd, London      19 August 1987
;  Macro for writing an ascii text file using AutoCAD text entities.
;  The function can be used in conjunction with LTEXT.LSP
;**************************************************************************
(defun C:WTEXT (/ a c ce e f l s ss ss2 x)
  (setq ce (getvar "CMDECHO"))
  (setvar "CMDECHO" 0)
  (while (not f)
      ; Prompt for name of file
      (initget 1)
      (setq f (getstring "\nFilename to write to: "))
      (setq a (open f "r")) ; Test whether file already exists
      ; option if file already exists
      (if a
        (progn
         (prompt (strcat "\nFile " (strcase f) " already exists."))
         (initget "Append Overwrite New")
         (setq s (getkword "\nAppend/Overwrite or <New name>: "))
         (close a)
         (cond ((= s "Append") (setq f (open f "a")))
               ((= s "Overwrite") (setq f (open f "w")))
               (T (setq f nil))
         )
        )
        ; open file to write to
        (setq f (open f "w"))
      )
  )
  (while (null ss) (setq ss (ssget)))  ; create selection set
                                       ; of entities to process
  (setq ss2 (ssadd))
  (setq c 0)
  (setq e (ssname ss c))
  (while e
       (setq e (entget e))
       (if (= (cdr (assoc 0 e)) "TEXT")
           (progn
            (setq l (cdr (assoc 1 e)))
            (if l (write-line l f))
            (ssadd (cdar e) ss2)
           )
       )
       (setq c (1+ c))
       (setq e (ssname ss c))
  )
  (close f)
  (initget "Yes No")
  (setq x (getkword "\nDelete selected text entities <N>: "))
  (if (= x "Yes") (command "ERASE" ss2 ""))
  (setvar "CMDECHO" ce)
  (princ)
)