Как получить длину линии?

Public Function PerimeterOb(Ob As AcadEntity) As Double
Dim VarTyp As String
    VarTyp = TypeName(Ob)
    Select Case VarTyp
    Case "IAcadLWPolyline": PerimeterOb = PerimeterLWP(Ob)
    Case "IAcadCircle": PerimeterOb = PerimeterCirc(Ob)
    Case "IAcadLine": PerimeterOb = PerimeterLine(Ob)
    Case "IAcadArc": PerimeterOb = PerimeterArc(Ob)
    Case Else
        PerimeterOb = 0
    End Select
End Function
Public Function PerimeterLWP(LWP As AcadLWPolyline) As Double
Dim vrt As Variant
Dim nn As Long, n As Long
Dim vP As Double
Dim t0(1) As Double, t1(1) As Double, tc(1) As Double
Dim kr As Double, lseg As Double
    vP = 0
    On Error Resume Next
        vrt = LWP.Coordinates
    If Err Then
        Err.Clear
    End If
    nn = UBound(vrt)
    For n = 0 To nn - 2 Step 2
        t0(0) = vrt(n): t0(1) = vrt(n + 1)
        kr = LWP.GetBulge(n / 2)
        t1(0) = vrt(n + 2): t1(1) = vrt(n + 3)
        vP = vP + LenSegmPL(t0, t1, kr)
    Next n
    If LWP.Closed Then
        t0(0) = vrt(nn - 1): t0(1) = vrt(nn)
        kr = LWP.GetBulge(Int(nn / 2))
        t1(0) = vrt(0): t1(1) = vrt(1)
        vP = vP + LenSegmPL(t0, t1, kr)
    End If
    PerimeterLWP = vP
End Function
Public Function PerimeterCirc(Cir As AcadCircle) As Double
Dim vP As Double
    vP = 0
    On Error Resume Next
        vP = Cir.Circumference
    If Err Then
        Err.Clear
    End If
    PerimeterCirc = vP
End Function
Public Function PerimeterLine(Line As AcadLine) As Double
Dim vP As Double
    vP = 0
    On Error Resume Next
        vP = Line.Length
    If Err Then
        Err.Clear
    End If
    PerimeterLine = vP
End Function
Public Function PerimeterArc(Arc As AcadArc) As Double
Dim vP As Double
    vP = 0
    On Error Resume Next
        vP = Arc.ArcLength
    If Err Then
        Err.Clear
    End If
    PerimeterArc = vP
End Function

Public Sub LenLine()
    Dim Obj As AcadEntity
    Dim SelSet As AcadSelectionSet
    Dim SumLen As Double
    Dim A As Long
    Dim ObjExpl() As AcadEntity
On Error GoTo Control 'Ловим ошибку на тот случай, если пользователь нажмет "Esc"
    Set SelSet = ThisDrawing.SelectionSets.Add("Set") 'Создаем новый набор выбора, например с именем "Set"
On Error GoTo 0
    SelSet.SelectOnScreen 'Запрос на выбор примитивов
    If SelSet.Count = 0 Then GoTo Control
    For Each Obj In SelSet
        SumLen = SumLen + LenObj(Obj)
    Next Obj
    PrintMessage "Сумма длин " & SelSet.Count & " элементов = " & SumLen
Control:
    SelSet.Delete 'Удаляем набор выбора
End Sub
Private Function LenObj(Obj As AcadEntity) As Double
    Dim Ln As AcadLine
    Dim Pl As AcadLWPolyline  'AcadPolyline
    Dim Ci As AcadArc
    Dim ObjExpl() As AcadEntity
    Dim A As Long
    If Obj.ObjectName = "AcDbLine" Then
        Set Ln = Obj
        LenObj = Ln.Length
        Set Ln = Nothing
    ElseIf Obj.ObjectName = "AcDbPolyline" Then
        Set Pl = Obj
        ObjExpl() = Pl.Explode
        For A = 0 To UBound(ObjExpl()) - 1
            LenObj = LenObj + LenObj(ObjExpl(A))
            ObjExpl(A).Delete
        Next A
        ObjExpl(A).Delete
        Set Pl = Nothing
    ElseIf Obj.ObjectName = "AcDbArc" Then
        Set Ci = Obj
        LenObj = LenObj + Ci.ArcLength
        Set Ci = Nothing
    Else
        MsgBox "Объект с именем " & Obj.ObjectName & " не включен в расчет", vbCritical
    End If
    'Obj.Update'Обновляем объект
End Function
Public Sub PrintMessage(MessageString As String)
Dim pEchoVal As Integer
    pEchoVal = ThisDrawing.GetVariable("CMDECHO")
    ThisDrawing.SetVariable "CMDECHO", 1
    ThisDrawing.Utility.Prompt MessageString
    ThisDrawing.SetVariable "CMDECHO", pEchoVal
End Sub

Public Function Distance(ByVal t0 As Variant, ByVal t1 As Variant) As Double
        Distance = Sqr(((t1(0) - t0(0)) ^ 2) + ((t1(1) - t0(1)) ^ 2))
End Function