Как программно измерить длину труб в 3D-чертеже? (Страница 1 из 2)

;аргументы:
;dia1 - наружный диаметр
;dia2  - иунутренний диаметр
(defun pipl (dia1 dia2 / adoc axss dia len_list)
    (vl-load-com)
   (setq    adoc (vla-get-activedocument
           (vlax-get-acad-object)
         )
  )
  (if (ssget (list (cons 0 "3DSOLID")))
    (progn
      (setq rad1 (/ dia1 2)
        rad2 (/ dia2 2)
        sv (- (* pi (expt rad1 2))(* pi (expt rad2 2))))
      (setq axss (vla-get-activeselectionset adoc))
      (vlax-for a axss
    (setq len_list (cons (/ (vlax-get a 'Volume) sv) len_list)))))
  (apply '+ len_list)
  )
;Вызов :
(setq pipe_length (pipl dia1 dia2))

(defun total-pipe-length (/ acsp adoc axss dia1 dia2 ll
              pt_list rad1 rad2 sum_volume
              sv total_length total_volume
              unit_volume ur)
  (vl-load-com)
  (setq    adoc (vla-get-activedocument
           (vlax-get-acad-object)
         )
  )
  (if (and
    (= (getvar "tilemode") 0)
    (= (getvar "cvport") 1)
      )
    (setq acsp (vla-get-paperspace adoc))
    (setq acsp (vla-get-modelspace adoc))
  )
(setq dia1 89. dia2 76.); в миллиметрах
       (setq rad1 (/ dia1 2 1000);  в метрах
         rad2 (/ dia2 2 1000);  в метрах
        sv (* pi (- (expt rad1 2)(expt rad2 2)))); в кв. метрах
(setq unit_volume sv); объем погонного метра трубы в куб. метрах
(ssget "_X" (list (cons 0 "3DSOLID")))
(setq axss (vla-get-activeselectionset adoc)
      sum_volume 0.)
(vlax-for a axss
  (vla-getboundingbox a 'll 'ur)
  (setq ll (vlax-safearray->list ll)
    ur (vlax-safearray->list ur))
  (setq pt_list (cons ll (cons ur pt_list)))
  (setq sum_volume (+ sum_volume (vlax-get a 'Volume)))); в куб. миллиметрах
  (setq sum_volume (/ sum_volume 1e+009)); в куб. метрах
  (setq total_length (/ sum_volume unit_volume));  в метрах
(vla-clear axss)
(vla-delete axss)
(vlax-release-object axss)
(setq total_length (/ sum_volume unit_volume));в метрах
(alert (strcat "Total: \n" (rtos ( / total_length) 2 2) " meters"))
  )
;Вызов :
(setq sum_pipes_length (total-pipe-length))

(defun all-layers-by-mask (mask / all_lyrs lyr_list)
  (if mask
  (progn
  (setq all_lyrs (vla-get-layers adoc))
  (vlax-for a all_lyrs
    (if (wcmatch (strcase (vla-get-name a))(strcase (strcat mask "*")))
      (setq lyr_list (cons (vla-get-name a) lyr_list))))
  (acad_strlsort lyr_list))))
(defun get-layer-by-diam (mask diam  / dlyrs)
(foreach i (all-layers-by-mask mask)
  (if (wcmatch (strcase i) (strcase (strcat "*" (itoa diam) "*")))
    (setq dlyrs (cons i dlyrs))))
(acad_strlsort dlyrs))
(defun filter-layer (lname /)
  (list (cons 0 "3DSOLID")(cons 8 lname)))
(defun get-ext-dia (diam)
  (cond
  ((equal diam 10. 0.001) 15.)
  ((equal diam 15. 0.001) 20.)
  ((equal diam 20. 0.001) 25.)
  ((equal diam 25. 0.001) 30.)
  ((equal diam 32. 0.001) 38.)
  ((equal diam 40. 0.001) 45.)
  ((equal diam 50. 0.001) 57.)
  ((equal diam 65. 0.001) 76.)
  ((equal diam 80. 0.001) 89.)
  ((equal diam 100. 0.001) 112.);=>corrected value
  ((equal diam 125. 0.001) 133.)
  ((equal diam 150. 0.001) 159.)
  ((equal diam 200. 0.001) 220.)
  ((equal diam 250. 0.001) 273.)
  ((equal diam 300. 0.001) 324.)))
(defun sel-dial ()
;;;(setq fname (vl-filename-mktemp "liso.dcl"))
(setq fname (strcat (getvar "dwgprefix") "pipe-len.dcl"))
(setq fn (open fname "w"))
(write-line
"sel_layer : dialog {" fn)
(write-line (strcat "label = " "\"" "SELECT LAYER TO GET LENGTH" "\"" ";") fn)
(write-line  "spacer_1;" fn)
(write-line  ":list_box {" fn)
(write-line (strcat "key = " "\""  "alist" "\"" ";") fn)
(write-line (strcat "label = " "\""  "Layer list" "\"" ";") fn)
(write-line "width=45;" fn)
(write-line "height=10;" fn)
(write-line "allow_accept=true;" fn)
(write-line "multiple_select=false;}" fn)
(write-line "spacer_0;" fn)
(write-line "spacer_0;" fn)
(write-line "ok_cancel;}" fn)
(close fn)
)
;=================main programm===================
(defun C:pi (/ acsp adoc all_layers axss choice
          ;|comp_data|; ;=> global
          dcl_id dia1 dia2 diam filt
          ;|fname|; ;=> global
          ll lyr
          mask pipe_len_list pt_list rad1 rad2
          sum_volume sv total_length tmp unit_volume ur)
(setvar "cmdecho" 0)
(setvar "expert" 2)
  (vl-load-com)
  (setq  adoc (vla-get-activedocument
         (vlax-get-acad-object)
       )
  )
  (if (and
  (= (getvar "tilemode") 0)
  (= (getvar "cvport") 1)
      )
    (setq acsp (vla-get-paperspace adoc))
    (setq acsp (vla-get-modelspace adoc))
  )
 (setq mask "DN");layer mask, i.e.: "DN 150 piping for vent from cyclone"
 (while
  (setq diam (getint "\nInner diameter [Enter to stop]: \n"))
(setq all_layers (get-layer-by-diam mask diam))
(sel-dial)
(setq dcl_id (load_dialog fname))
(new_dialog "sel_layer" dcl_id)
      (start_list "alist")
      (mapcar 'add_list all_layers)
      (end_list)
      (action_tile "alist" "(setq choice $value)")
      (start_dialog)
      (unload_dialog dcl_id)
      (done_dialog)
      (vl-file-delete fname)
(if choice
  (progn
  (setq lyr (nth (atoi choice) all_layers))
  (setq filt (filter-layer lyr))
  (ssget "_X" filt)
  (setq dia2 diam dia1 (get-ext-dia diam))
  (setq axss (vla-get-activeselectionset adoc))
  (if axss
    (progn
 (setq rad1 (/ dia1 2.)
       rad2 (/ dia2 2.)
      sv (* pi (- (expt rad1 2)(expt rad2 2))))
(setq unit_volume sv)
(setq sum_volume 0.)
(vlax-for a axss
  (setq tmp (vlax-get a 'Volume))
  (setq sum_volume (+  tmp sum_volume)))
  (setq total_length (/  sum_volume unit_volume 1000.))
  (setq pipe_len_list (strcat "Layer: " lyr "\n"
                  "Diameter: " (itoa diam) "\n"            
                  "Length: " (rtos total_length 2 5) " метров"))
  (setq comp_data (cons pipe_len_list comp_data))
  (alert (vl-princ-to-string pipe_len_list))
(vla-clear axss)
(vla-delete axss)
(vlax-release-object axss))
    (progn
      (alert "No pipes on this layer!")
      )
    )
    )
(alert "\nNo layers selected!")
)
  )
(setvar "cmdecho" 1)
(setvar "expert" 0)
(princ)
)
(prompt "\n")
(prompt "\t\t<<< Type pi to execute :  >>>  \n")
(princ)
;;;TesT : (C:pi)
~'J'~