Как получить текущие координаты курсора в простр. модели

Sub Example_GetPoint()
    ' This example returns a point entered by the user.
    Dim returnPnt As Variant
    ' Return a point using a prompt
    returnPnt = ThisDrawing.Utility.GetPoint(, "Enter a point: ")
    MsgBox "The WCS of the point is: " & returnPnt(0) & ", " & returnPnt(1) & ", " & returnPnt(2) & vbCrLf & _
            "(Enter the next value without prompting.)", , "GetPoint Example"
    ' Return a point, no prompt
    returnPnt = ThisDrawing.Utility.GetPoint
    MsgBox "The WCS of the point is: " & returnPnt(0) & ", " & returnPnt(1) & ", " & returnPnt(2), , "GetPoint Example"
    ' Return a point using a base point and a prompt
    Dim basePnt(0 To 2) As Double
    basePnt(0) = 2#: basePnt(1) = 2#: basePnt(2) = 0#
    returnPnt = ThisDrawing.Utility.GetPoint(basePnt, "Enter a point: ")
    MsgBox "The WCS of the point is: " & returnPnt(0) & ", " & returnPnt(1) & ", " & returnPnt(2)
    ' Create a line from the base point and the last point entered
    Dim lineObj As AcadLine
    Set lineObj = ThisDrawing.ModelSpace.AddLine(basePnt, returnPnt)
    ZoomAll
End Sub

Option Explicit
Type POINTAPI
    X   As Long
    Y   As Long
End Type
Type rect
     Left As Long
     Top As Long
     Right As Long
     Bottom As Long
End Type
Public Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Public Declare Function ScreenToClient Lib "user32" (ByVal hwnd As Long, lpPoint As POINTAPI) As Long
Public Declare Function GetClientRect Lib "user32" (ByVal hwnd As Long, lpRect As rect) As Long
Sub CursorPos()
'получение экранных координат курсора
    Dim retValue As Long
    Dim CursorLoc As POINTAPI
    retValue = GetCursorPos(CursorLoc)
'дескриптор активного окна
    Dim vHWND As Long
    If Documents.Count = 0 Then
        MsgBox "There are no open documents!"
        Exit Sub
    End If
    vHWND = ActiveDocument.hwnd
    ''размер клиентской области (в писелях)
    '    Dim vRect As rect
    '    retValue = GetClientRect(ByVal vHWND, vRect)
'размер клиентской области (в писелях)
'этот размер с точки зрения AutoCAD насколько отличается
'от размера с точки зрения Windows.
'В итоге, автокадовсий подход дает более точный результат
    Dim vRect As rect
    Dim SizeOfScreen As Variant
    SizeOfScreen = ThisDrawing.GetVariable("SCREENSIZE")
    vRect.Right = SizeOfScreen(0)
    vRect.Bottom = SizeOfScreen(1)
'перевод экранных координат в клиентские
    retValue = ScreenToClient(ByVal vHWND, CursorLoc)
'высота вида (клиентской области)в USC:
    Dim HeightScreen As Long
    HeightScreen = ThisDrawing.GetVariable("VIEWSIZE")
'ширина вида (клиентского экрана)в USC:
    Dim WidthScreen As Long
    WidthScreen = HeightScreen * vRect.Right / vRect.Bottom
'положение центра клиентской области в USC:
    Dim СenterScreen As Variant
    СenterScreen = ThisDrawing.GetVariable("VIEWCTR")
'положение левого нижнего угла клиентской области в USC:
    Dim X0 As Double
    Dim Y0 As Double
    X0 = СenterScreen(0) - WidthScreen / 2
    Y0 = СenterScreen(1) - HeightScreen / 2
'масштабный коэффициент для пересчета координат из пикселей в единицы чертежа
    Dim K_Coord_ScreenToWCS As Single
    K_Coord_ScreenToWCS = HeightScreen / vRect.Bottom
'позиция курсора в USC:
    Dim X_CursorPos As Double
    Dim YCursorPos As Double
    X_CursorPos = X0 + K_Coord_ScreenToWCS * CursorLoc.X
    YCursorPos = Y0 + (HeightScreen - K_Coord_ScreenToWCS * CursorLoc.Y)
    MsgBox "X = " & X_CursorPos & vbCrLf & "Y = " & YCursorPos
End Sub