Как заполнить поля Properties? (Страница 1 из 2)

^C^C_setvar;dimtol;1;;dimlim;0;;dimtp;0.02;;dimtm;0;;dimtfac;0.6;

;|
*    Параметры вызова:
*    lst    список изменяемых параметров вида:
      '(("show" . t)        ; ToleranceDisplay. nil -> скрывать. acTolNone | acTolSymmetrical | acTolDeviation | acTolLimits | acTolBasic
    ("height" . 0.65)    ; ToleranceHeightScale. nil -> 0.65
    ("just" . 1)        ; ToleranceJustification : acTolTop | acTolMiddle | acTolBottom
                ; nil -> acTolMiddle
    ("low" . 0.5)        ; ToleranceLowerLimit. nil -> 0.0
    ("up" . 0.5)        ; ToleranceUpperLimit. nil -> "low".
    ("prec" . 2)        ; TolerancePrecision. nil -> (getvar "luprec")
    ("lead" . :vlax-true)    ; ToleranceSuppressLeadingZeros. nil -> :vlax-false
    ("trail" . :vlax-true)    ; ToleranceSuppressTrailingZeros. nil -> :vlax-false
    )
*    Примеры вызова:
LISP:
;; Поставить несимметричные tolerance, высота текста 0,5, нижний лимит - 0,65; верхний - 0,758, точность отображения - 3 символа после запятой.
;; Нули не подавлять - ни начальные, ни конечные.
(chdim (list (cons "show" acTolDeviation) '("height" . 0.5) '("low" . 0.65) '("up" . 0.758) '("prec" . 3)))
;; Поставить симметричные Tolerance. Высота текста 0,5, лимит 0,65, точность отображения 3
(chdim (list (cons "show" acTolSymmetrical) '("height" . 0.5) '("low" . 0.65) '("prec" . 3)))
;; Снять tolerance
(chdim nil)
DIESEL:
^C^C^P(chdim (list (cons "show" acTolDeviation) '("height" . 0.5) '("low" . 0.65) '("up" . 0.758) '("prec" . 3)))
^C^C^P(chdim (list (cons "show" acTolSymmetrical) '("height" . 0.5) '("low" . 0.65) '("prec" . 3)))
^C^C^P(chdim nil)
|;
(defun chdim (lst /)
  (foreach ent (mapcar 'vlax-ename->vla-object
                       (vl-remove-if
                         'listp
                         (mapcar 'cadr (ssnamex (ssget '((0 . "DIMENSION")))))
                         ) ;_ end of vl-remove-if
                       ) ;_ end of mapcar
    (if (cdr (assoc "show" lst))
      (if (vlax-property-available-p ent "ToleranceDisplay" t)
        (progn
          (vl-catch-all-apply
            '(lambda () (vla-put-tolerancedisplay ent (cdr (assoc "show" lst))))
            ) ;_ end of vl-catch-all-apply
          (vl-catch-all-apply
            '(lambda ()
               (vla-put-toleranceheightscale
                 ent
                 (cond
                   ((cdr (assoc "height" lst)))
                   (t 0.65)
                   ) ;_ end of cond
                 ) ;_ end of vla-put-toleranceheightscale
               ) ;_ end of lambda
            ) ;_ end of vl-catch-all-apply
          (vl-catch-all-apply
            '(lambda ()
               (vla-put-tolerancejustification
                 ent
                 (cond
                   ((cdr (assoc "just" lst)))
                   (t actolmiddle)
                   ) ;_ end of cond
                 ) ;_ end of vla-put-tolerancejustification
               ) ;_ end of lambda
            ) ;_ end of vl-catch-all-apply
          (vl-catch-all-apply
            '(lambda ()
               (vla-put-tolerancelowerlimit
                 ent
                 (cond ((cdr (assoc "low" lst)))
                       (t 0.0)
                       ) ;_ end of cond
                 ) ;_ end of vla-put-ToleranceLowerLimit
               ) ;_ end of lambda
            ) ;_ end of vl-catch-all-apply
          (vl-catch-all-apply
            '(lambda ()
               (vla-put-toleranceupperlimit
                 ent
                 (cond ((cdr (assoc "up" lst)))
                       (t (vla-get-tolerancelowerlimit ent))
                       ) ;_ end of cond
                 ) ;_ end of vla-put-ToleranceUpperLimit
               ) ;_ end of lambda
            ) ;_ end of vl-catch-all-apply
          (vl-catch-all-apply
            '(lambda ()
               (vla-put-toleranceprecision
                 ent
                 (cond ((cdr (assoc "prec" lst)))
                       (t (getvar "luprec"))
                       ) ;_ end of cond
                 ) ;_ end of vla-put-TolerancePrecision
               ) ;_ end of lambda
            ) ;_ end of vl-catch-all-apply
          (vl-catch-all-apply
            '(lambda ()
               (vla-put-tolerancesuppressleadingzeros
                 ent
                 (cond ((cdr (assoc "lead" lst)))
                       (t :vlax-false)
                       ) ;_ end of cond
                 ) ;_ end of vla-put-ToleranceSuppressLeadingZeros
               ) ;_ end of lambda
            ) ;_ end of vl-catch-all-apply
          (vl-catch-all-apply
            '(lambda ()
               (vla-put-tolerancesuppresstrailingzeros
                 ent
                 (cond ((cdr (assoc "trail" lst)))
                       (t :vlax-false)
                       ) ;_ end of cond
                 ) ;_ end of vla-put-ToleranceSuppressTrailingZeros
               ) ;_ end of lambda
            ) ;_ end of vl-catch-all-apply
          ) ;_ end of progn
        ) ;_ end of if
      (vl-catch-all-apply
        '(lambda () (vla-put-tolerancedisplay ent actolnone))
        ) ;_ end of vl-catch-all-apply
      ) ;_ end of if
    ) ;_ end of foreach
  ) ;_ end of defun