Редактирование отметок

отметки чего?  В каком виде имеющийся файл:3D или 2D? Какая программа, наконец?

:)Нельзя паниковать, вы правы))
Ситуация такая: есть dwg-файл с топографической съемкой, 2D. Все уже оформлено по всем правилам топографии, то есть часть отметок развернута. Но съемка не сидит по высоте... И теперь нужно каждую отметку изменить на полтора метра, а их там несколько тысяч.... Реально, конечно, подсадить в акад пересчитанные отметки, но редактура большого объекта займет много времени...Может можно это сделать "автоматом", или все оч. критично?

> Ирина
Да изложите же нормально. Кто же знает, что такое "отметка" в Вашем понимании да еще в вашем чертеже.
Отметка точки может быть проставлена разными способами - блоком с атрибутом, просто текстом. Отметка может быть у горизонтали и тоже разными способами.
Вы пишете про величину Z, тогда см. совет Igor' Kulikov (2006-11-21 05:51:23)
А я подозреваю, что надо текст надписей отметок изменить, т.к. в 2D Z не имеет значения. А кто-то еще что-то гнусное подумает.

1.Отметки-тексты соберите на одном слое. Других текстов на этом слое быть не должно. В следующем ответе назовите имя этого слоя.
2.Линейный текст - это _text  ?
3.Приведите образец. Важен разделитель.
4.Они все написаны в одинаковом стиле, с одинаковым выравниванием, или есть украшения (влево-вправо)? Если Вам нечего ответить на этот вопрос, то это плюс в нашем деле.
5.Думаю, что сегодня вечером мы перепишем Ваши тексты :о)
Чуть-чуть поумничаю. А что значит в Автокаде -2D? По-моему, только то, что Z равен 0, то есть его не ввели..

Кстати,ко всем отметкам надо прибавить 1.5 метра

Без циклической обработки:

(defun c:chtxt (/ adoc delta selset)
  (vl-load-com)
  (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
  (vla-startundomark adoc)
  (if (and (setq delta (getreal "\nВведите разность значений <ВЫход> : "))
           (setq selset (ssget '((0 . "*TEXT"))))
           ) ;_ end of and
    (foreach ent (mapcar 'vlax-ename->vla-object
                         (vl-remove-if 'listp (mapcar 'cadr (ssnamex selset)))
                         ) ;_ end of mapcar
      (if ((lambda (/ res)
             (mapcar '(lambda (x)
                        (if (vl-string-search x (vla-get-textstring ent))
                          (setq res t)
                          ) ;_ end of if
                        ) ;_ end of lambda
                     '("1" "2" "3" "4" "5" "6" "7" "8" "9" "0" "," ".")
                     ) ;_ end of mapcar
             res
             ) ;_ end of lambda
           )
        (vl-catch-all-apply
          '(lambda ()
             (vla-put-textstring
               ent
               (rtos
                 (+ (atof (vl-string-translate "," "." (vla-get-textstring ent)))
                    delta
                    ) ;_ end of +
                 ) ;_ end of rtos
               ) ;_ end of vla-put-TextString
             ) ;_ end of lambda
          ) ;_ end of vl-catch-all-apply
        ) ;_ end of if
      ) ;_ end of foreach
    ) ;_ end of if
  (vla-endundomark adoc)
  (princ)
  ) ;_ end of defun

Работу кода не проверял, писалось практически на коленке, оставляю как есть.

В догонку: imja_sloja[rus] zamenit' na svojo.
...Poka pisal, von skol'ko natvorili .... zato u menja bez [/rus] VLisp'a.  Да и короче получилось

Ну и ещё один вариант
(defun c:text-vo ( / )
  (setq z_!(getreal "\nЗадайте приращение по Z в виде zzz.zz : "))
  (setq iln_$(getstring "\nВведите имя слоя с текстами высотных отметок:"))
  (setq nabor_L (ssget "X" (list(cons 0 "TEXT")(cons 8 iln_$))))
  (if nabor_L
    (progn
     (setq nabor_%(sslength nabor_L) ne_% 0)
     (setvar "CMDECHO" 0)
     (command "_-layer" "_m" (strcat iln_$ "_new") "")
     (command "_-style" "" "" "0" "" "" "" "" "")
     (repeat nabor_%
          (setq              name(ssname nabor_L ne_%) ent_L(entget name)
        v1(cdr(assoc '10 ent_L)) h1_!(cdr(assoc '40 ent_L))
        r_!(* 180(/(cdr(assoc '50 ent_L))pi))
        txt_$(rtos(+(atof(cdr(assoc '1 ent_L)))z_!) 2 2)
          );setq
         (command "_text" v1 h1_! r_! txt_$ "")
         (setq ne_%(1+ ne_%))
     );repeat
   );progn
   (print (strcat "На слое "  iln_$ " нет текстов "))
  );if nabor_L
(setvar "CMDECHO" 1)
(prin1)
);c:text-vo
Добро это скопируй в файл "text-vo.lsp", помести в тот каталог, где живёт рисунок.dwg
Очень советую с риcунка сделать копию ::о(
Загрузишь рисунок, набери (load "text-vo")
Появится сообщение, что есть новая команда text-vo
Набери text-vo и введи изменение по Z и имя слоя с отметками.
Буден создан новый слой и на нём написаны новые отметки.

Всем огромное спасибо.Запустила программку,предложенную kpblом.Супер!Спасли от бессонных ночей:))Спасибо от всех девчонок нашего отдела(такая проблема уже не раз возникала,но на маленьких объектах и мы особо не заморачивались).

P.S. Со слоями, кстати, тоже не обрабатывал. Их надо предварительно приводить в изменяемый вид либо руками, либо программно. Но программное решение приведет к такому увеличению кода, что мама не горюй.