EnumWindows возвращает Handle, помогите через Handle получить GUID

Можно, используя дескриптор окна, извлечь путь к exe-шнику.
Option Explicit
Private Declare Function GetWindowThreadProcessId Lib "user32" ( _
   ByVal hWnd As Long, lpdwProcessId As Long) As Long
Private Declare Function OpenProcess Lib "kernel32" ( _
   ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, _
   ByVal dwProcessId As Long) As Long
Private Const PROCESS_VM_READ = &H10
Private Const PROCESS_QUERY_INFORMATION = &H400
Private Declare Function CloseHandle Lib "kernel32" ( _
   ByVal hObject As Long) As Long
Private Declare Function CreateToolhelp32Snapshot Lib "kernel32" ( _
   ByVal dwFlags As Long, ByVal th32ProcessID As Long) As Long
Private Const TH32CS_SNAPMODULE = &H8
Private Const MAX_PATH = 260
Private Const MAX_MODULE_NAME32 = 255
Private Type MODULEENTRY32
   dwSize As Long
   th32ModuleID As Long
   th32ProcessID As Long
   GlblcntUsage As Long
   ProccntUsage As Long
   modBaseAddr As Long
   modBaseSize As Long
   hModule As Long
   szModule(0 To MAX_MODULE_NAME32) As Byte
   szExePath(0 To MAX_PATH - 1) As Byte
End Type
Private Declare Function Module32First Lib "kernel32" ( _
  ByVal hSnapshot As Long, lpme As MODULEENTRY32) As Long
Private Const INVALID_HANDLE_VALUE As Long = -1&
Public Function GetExePathFromhWnd(ByVal hWnd As Long) As String
 Dim ProcessId As Long
 Dim hProcess As Long
 Dim hModuleSnap As Long
 Dim me32 As MODULEENTRY32
 Dim sExePath As String
 GetWindowThreadProcessId hWnd, ProcessId
 If ProcessId = 0 Then Exit Function
 hProcess = OpenProcess(PROCESS_QUERY_INFORMATION, 0, ProcessId)
 If hProcess = 0 Then Exit Function
 hModuleSnap = CreateToolhelp32Snapshot(TH32CS_SNAPMODULE, ProcessId)
 If hModuleSnap = INVALID_HANDLE_VALUE Then CloseHandle hProcess: Exit Function
 me32.dwSize = LenB(me32)
 If Module32First(hModuleSnap, me32) Then
    sExePath = StrConv(me32.szExePath, vbUnicode)
    GetExePathFromhWnd = Left$(sExePath, InStr(sExePath, vbNullChar) - 1)
 End If
 CloseHandle hModuleSnap
 CloseHandle hProcess
End Function