Метод Select объекта SelectionSets, порядок выделения

'~~~~~~~~~~~~~~~~Sort two-dimensional array~~~~~~~~~~~~'
' written by Fatty T.O.H. (c)2006 * all rights removed '
' SourceArr - two dimensional array                    '
' iPos - column number to sort by (starting from 1)    '
'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
Public Function ColSort(SourceArr As Variant, iPos As Integer) As Variant
     Dim Check As Boolean
     ReDim tmpArr(UBound(SourceArr, 2)) As Variant
     Dim iCount As Integer
     Dim jCount As Integer
     Dim nCount As Integer
     iPos = iPos - 1
     Check = False
     Do Until Check
          Check = True
          For iCount = LBound(SourceArr, 1) To UBound(SourceArr, 1) - 1
               If SourceArr(iCount, iPos) > SourceArr(iCount + 1, iPos) Then
                    For jCount = LBound(SourceArr, 2) To UBound(SourceArr, 2)
                         tmpArr(jCount) = SourceArr(iCount, jCount)
                         SourceArr(iCount, jCount) = SourceArr(iCount + 1, jCount)
                         SourceArr(iCount + 1, jCount) = tmpArr(jCount)
                         Check = False
                    Next
               End If
          Next
     Loop
     ColSort = SourceArr
End Function
Sub DrawOnTops()
     Dim oSset As AcadSelectionSet
     Dim ftype(0) As Integer
     Dim fData(0) As Variant
     Dim oEnt As AcadEntity
     Dim oLine As AcadLine
     Dim oPline As AcadPolyline
     Dim stPt As Variant
     Dim endPt As Variant
     Dim sortedArr As Variant
     Dim i As Integer
     On Error Resume Next
     If Not IsNull(ThisDrawing.SelectionSets.Item("$SortLines$")) Then
          Set oSset = ThisDrawing.SelectionSets.Item("$SortLines$")
          oSset.Delete
     End If
     Set oSset = ThisDrawing.SelectionSets.Add("$SortLines$")
     ftype(0) = 0: fData(0) = "LINE"
     oSset.SelectOnScreen ftype, fData
     ReDim ptarr(0 To oSset.Count - 1, 0 To 2) As Variant
     For Each oEnt In oSset
          Set oLine = oEnt
          stPt = oLine.StartPoint
          endPt = oLine.EndPoint
          If stPt(1) > endPt(1) Then
               ptarr(i, 0) = stPt(0): ptarr(i, 1) = stPt(1): ptarr(i, 2) = stPt(2)
          Else
               ptarr(i, 0) = endPt(0): ptarr(i, 1) = endPt(1): ptarr(i, 2) = endPt(2)
          End If
          i = i + 1
     Next
     sortedArr = ColSort(ptarr, 1)     '<--sort by first subitem (by X coordinate)
     ReDim coordArr((UBound(sortedArr, 1) + 1) * 3 - 1) As Double
     Dim n As Integer
     For i = 0 To UBound(sortedArr, 1)
          coordArr(n) = sortedArr(i, 0): coordArr(n + 1) = sortedArr(i, 1): coordArr(n + 2) = sortedArr(i, 2)
          n = n + 3
     Next
     Set oPline = ThisDrawing.ModelSpace.AddPolyline(coordArr)
     oSset.Delete
     Set oSset = Nothing
End Sub