Как на VBA поместить объект на задний фон

Option Explicit
Sub OrderToBottom()
' This example creates a SortentsTable object and
' changes the draw order of selected object(s) to bottom.
     Dim oSset As AcadSelectionSet
     Dim oEnt
     Dim i As Integer
     Dim setName As String
     setName = "$Order$"
     'Make sure selection set does not exist
     For i = 0 To ThisDrawing.SelectionSets.Count - 1
          If ThisDrawing.SelectionSets.Item(i).Name = setName Then
               ThisDrawing.SelectionSets.Item(i).Delete
               Exit For
          End If
     Next i
     Set oSset = ThisDrawing.SelectionSets.Add(setName)
     oSset.SelectOnScreen
     If oSset.Count > 0 Then
          ReDim arrObj(0 To oSset.Count - 1) As AcadObject
          'Process each object
          i = 0
          For Each oEnt In oSset
               Set arrObj(i) = oEnt
               i = i + 1
          Next
     End If
     On Error GoTo Err_Control
     'Gxet an extension dictionary and, if necessary, add a SortentsTable object
     Dim eDictionary As Object
     Set eDictionary = ThisDrawing.ModelSpace.GetExtensionDictionary
     ' Prevent failed GetObject calls from throwing an exception
     On Error Resume Next
     Dim sentityObj As Object
     Set sentityObj = eDictionary.GetObject("ACAD_SORTENTS")
     On Error GoTo 0
     If sentityObj Is Nothing Then
          ' No SortentsTable object, so add one
          Set sentityObj = eDictionary.AddObject("ACAD_SORTENTS", "AcDbSortentsTable")
     End If
     'Move selected object(s) to the bottom
     sentityObj.MoveToBottom arrObj
     Application.Update
     Exit Sub
Err_Control:
     If Err.Number <> 0 Then MsgBox Err.Description
End Sub