ошибка: настройка переменной AutoCAD была отвергнута 2 (Страница 1 из 2)

(vl-load-com)
(defun Test (Path / FilesObj)
  (setq FilesObj (vla-get-Files (vla-get-Preferences (vlax-get-acad-object))))
  (list    (vla-get-PrintSpoolerPath FilesObj)
    (vla-get-PrinterConfigPath FilesObj)
    (vla-get-PrinterDescPath FilesObj)
    (car (list (vla-get-PrinterStyleSheetPath FilesObj)
           (vlax-release-object FilesObj)
         )
    )
  )
)

(defun set-paths (lst / files)
                 ;|
*    Установка путей поддержки плоттеров
*    Параметры вызова:
    lst    список вида:
      '(("spool" . <Printer spooler file location>)    ; nil -> Использовать
                                  ; каталог temp
        ("config" . <Printer config search path>)    ; nil ->
        ; (vl-registry-read (strcat "HKEY_LOCAL_MACHINE\\" (vlax-product-key)"\\aeccabinet\\directories")"NIWPLOTTERS")
        ("style" . <Printer style sheet path>)        ; nil ->
        ; (vl-registry-read (strcat "HKEY_LOCAL_MACHINE\\" (vlax-product-key)"\\aeccabinet\\directories")"NIWPLOTSTYLES")
|;
  (vl-load-com)
  (setq files (vla-get-files (vla-get-preferences (vlax-get-acad-object))))
  (vl-catch-all-apply
    '(lambda ()
       (vla-put-printspoolerpath
         files
         (cond
           ((cdr (assoc "spool" lst)))
           (t (vla-get-tempfilepath files))
           ) ;_ end of cond
         ) ;_ end of vla-put-printspoolerpath
       ) ;_ end of lambda
    ) ;_ end of vl-catch-all-apply
  (vl-catch-all-apply
    '(lambda ()
       (vla-put-printerconfigpath
         files
         (cond ((cdr (assoc "config" lst)))
               (t
                (vl-registry-read
                  (strcat "HKEY_LOCAL_MACHINE\\"
                          (vlax-product-key)
                          "\\aeccabinet\\directories"
                          ) ;_ end of strcat
                  "NIWPLOTTERS"
                  ) ;_ end of vl-registry-read
                )
               ) ;_ end of cond
         ) ;_ end of vla-put-PrinterConfigPath
       ) ;_ end of lambda
    ) ;_ end of vl-catch-all-apply
  (vl-catch-all-apply
    '(lambda ()
       (vla-put-printerstylesheetpath
         files
         (cond ((cdr (assoc "style" lst)))
               (t
                (vl-registry-read
                  (strcat "HKEY_LOCAL_MACHINE\\"
                          (vlax-product-key)
                          "\\aeccabinet\\directories"
                          ) ;_ end of strcat
                  "NIWPLOTSTYLES"
                  ) ;_ end of vl-registry-read
                )
               ) ;_ end of cond
         ) ;_ end of vla-put-PrinterStyleSheetPath
       ) ;_ end of lambda
    ) ;_ end of vl-catch-all-apply
  ) ;_ end of defun