• TK
  • Восстановленный участник
  • На форуме с 15 ноября 2007г.
  • Сообщений: 3
  • Спасибо: 0

Тема: Обращение к параметрам объектов в SelectionSet

Есть обеъкты, хранящиеся в наборе, нужно получить доступ к параметрам примитивов в него входящих. Т.е. программно, с помощью метода SelectionSet получен набор примитивов, надо поменять некоторые их параметры. Каким образом это можно сделать?

  • LeonidSN
  • Активный участник
  • На форуме с 30 мая 2005г.
  • Сообщений: 1,480
  • Спасибо: 5

Re: Обращение к параметрам объектов в SelectionSet

Dim ssetObj As AcadSelectionSet
    ssetObj.Select mode
    Dim objEnt As AcadEntity
    For Each objEnt In ssetObj
        objEnt.Color = acRed
        objEnt.Layer = "MyLaer"
        ---------------------
    Next objEnt

  • TK
  • Восстановленный участник
  • На форуме с 15 ноября 2007г.
  • Сообщений: 3
  • Спасибо: 0

Re: Обращение к параметрам объектов в SelectionSet

Это дает возможность их изменять, а мне надо получить их значения. Я непойму, как к ним добраться? Речь идет об Mtext, мне надо получить значения стиля, степень сжатия и т.п.

  • kpblc
  • kpblc
  • Активный участник
  • Откуда: С.-Петербург
  • На форуме с 29 ноября 2004г.
  • Сообщений: 8,348
  • Спасибо: 24

Re: Обращение к параметрам объектов в SelectionSet

obj.Style
obj.Width
Ну и т.п.

  • Fatty
  • Восстановленный участник
  • На форуме с 30 мая 2006г.
  • Сообщений: 989
  • Спасибо: 2

Re: Обращение к параметрам объектов в SelectionSet

> TK
Ты ведь когда в редакторе код набираешь, так
после того как ты ставишь точку, неужели не
видно в окне все свойства объекта?
Или в конце концов набери в редакторе:
AcadMText, потом выдели это и нажми всемогущую F1

Option Explicit
Sub DisplayProps()
Dim ssMText As AcadSelectionSet
Dim oEnt As AcadEntity
Dim oMText As AcadMText
Dim msg As String
Set ssMText = ThisDrawing.PickfirstSelectionSet
ssMText.Clear
Dim ftype(0) As Integer
Dim fdata(0) As Variant
ftype(0) = 0: fdata(0) = "MTEXT"
ssMText.SelectOnScreen ftype, fdata
If ssMText.Count > 0 Then
For Each oEnt In ssMText
msg = ""
Set oMText = oEnt
msg = msg & vbCr & "Style: " & vbTab & vbTab & oMText.StyleName
Dim oStyle As AcadTextStyle
Set oStyle = ThisDrawing.TextStyles(oMText.StyleName)
Dim dblWid As Double
dblWid = oStyle.Width
msg = msg & vbCr & "Text Height: " & vbTab & oMText.Height
msg = msg & vbCr & "Width Factor: " & vbTab & dblWid
msg = msg & vbCr & "Text Width: " & vbTab & Format(oMText.Width, "0.00")
msg = msg & vbCr & "Spacing Factor: " & vbTab & oMText.LineSpacingFactor
msg = msg & vbCr & "Rotation Angle: " & vbTab & oMText.Rotation
MsgBox msg
Next
End If
End Sub

~'J'~

  • TK
  • Восстановленный участник
  • На форуме с 15 ноября 2007г.
  • Сообщений: 3
  • Спасибо: 0

Re: Обращение к параметрам объектов в SelectionSet

Все замечательно работает, огромное спасибо!

  • LeonidSN
  • Активный участник
  • На форуме с 30 мая 2005г.
  • Сообщений: 1,480
  • Спасибо: 5

Re: Обращение к параметрам объектов в SelectionSet

> TK
Если в итоге получилось, то - прекрасно. Но все-таки, надо формулировать свой вопрос внятно!

> TK
получен набор примитивов, надо поменять некоторые их параметры.

> TK
Это дает возможность их изменять, а мне надо получить их значения