• ivan
  • Восстановленный участник
  • На форуме с 6 января 2008г.
  • Сообщений: 3
  • Спасибо: 0

Тема: Pleese help!!! Долго копирует автокад 2008

Ребята помогите как удалять мусор с файлов автокада чтобы копирование и вставка произошла быстрее а то у меня в некоторых файлов это длится минутами. Pleese HELP me!!!

  • kpblc
  • kpblc
  • Активный участник
  • Откуда: С.-Петербург
  • На форуме с 29 ноября 2004г.
  • Сообщений: 8,348
  • Спасибо: 24

Re: Pleese help!!! Долго копирует автокад 2008

Кроме как STW и RTFM и сказать-то мало что можно...
_purge (для диалога)
_-purge (для режима ком.строки и удаления записей о зарегистрированных приложениях)
+ удаление фильтров слоев.

  • Victor
  • Восстановленный участник
  • На форуме с 26 марта 2007г.
  • Сообщений: 270
  • Спасибо: 0

Re: Pleese help!!! Долго копирует автокад 2008

У нас тоже самое. Запускаем два автокада. Пока один копирует, в другом работаем :)  :(

  • Vova
  • Восстановленный участник
  • На форуме с 10 декабря 2003г.
  • Сообщений: 2,055
  • Спасибо: 0

Re: Pleese help!!! Долго копирует автокад 2008

Если у вас не 2006 или моложе, обратите внимание на последнюю строку сообщения от Кулик Алексей aka kpblc. Откройте мемеджер слоев, и там, с левой стороны, увидите, есть-ли лишнее. Если есть туча строк, сообщите сюда, вам выпишут лекарство.

  • kpblc
  • kpblc
  • Активный участник
  • Откуда: С.-Петербург
  • На форуме с 29 ноября 2004г.
  • Сообщений: 8,348
  • Спасибо: 24

Re: Pleese help!!! Долго копирует автокад 2008

> Vova
Это можно увидеть и в 2005-м. Насчет 2004-го не уверен, его установленного у меня нет, а так я не помню.

  • ivan
  • Восстановленный участник
  • На форуме с 6 января 2008г.
  • Сообщений: 3
  • Спасибо: 0

Re: Pleese help!!! Долго копирует автокад 2008

Я кое что нашел и должен сказать помогло и сейчас все чертежи у меня в порядке но правда ище не знаю как настраивать чтобы получить максимальный ефект. Называется прога SmartPurger 2.7 by JTB WORLD. Всем спасибо. Удачи.

  • Rust
  • Восстановленный участник
  • На форуме с 16 октября 2003г.
  • Сообщений: 270
  • Спасибо: 0

Re: Pleese help!!! Долго копирует автокад 2008

> ivan
Почаще применяй вот такой макрос:

^C^C_-purge _a ;_n

и такой не лишний будет:

^C^C(if (not C:ImgDet) (load "ImgDet")) ImgDet

  • Rust
  • Восстановленный участник
  • На форуме с 16 октября 2003г.
  • Сообщений: 270
  • Спасибо: 0

Re: Pleese help!!! Долго копирует автокад 2008

Извиняюсь, упустил

(defun C:ImgDet (/ all_raster_image_name image_set used_raster_image_name)
    (defun DetachImage (ImgName)
        (vl-catch-all-apply
            '(lambda ()
                 (vla-delete
                     (vla-item
                         (vla-item
                             (vla-get-dictionaries
                                 (vla-get-activedocument (vlax-get-acad-object))
                             ) ;_ end of vla-get-dictionaries
                             "ACAD_IMAGE_DICT"
                         ) ;_ end of vla-Item
                         ImgName
                     ) ;_ end of vla-Item
                 ) ;_ end of vla-Delete
             ) ;_ end of lambda
        ) ;_ end of vl-catch-all-apply
    ) ;_ end of defun
    (vl-load-com)
    (setvar "CMDECHO" 0)
    ;;Список всех растров
    (if
        (setq all_raster_image_name
                 (mapcar 'cdr
                         (vl-remove-if-not
                             (function (lambda (x) (= 3 (car x))))
                             (dictsearch (namedobjdict) "ACAD_IMAGE_DICT")
                         ) ;_ end of vl-remove-if-not
                 ) ;_ end of mapcar
        ) ;_ end of setq
           (setq all_raster_image_name (mapcar 'strcase all_raster_image_name))
    ) ;_ end of if
    ;;Список вставленных  растров
    (if (setq image_set (ssget "_X" '((0 . "IMAGE"))))
        (progn
            (setq used_raster_image_name
                     (mapcar
                         'vla-get-name
                         (mapcar 'vlax-ename->vla-object
                                 (vl-remove-if
                                     'listp
                                     (mapcar 'cadr (ssnamex image_set))
                                 ) ;_ end of vl-remove-if
                         ) ;_ end of mapcar
                     ) ;_ end of mapcar
            ) ;_ end of setq
            (setq used_raster_image_name (mapcar 'strcase used_raster_image_name))
        ) ;_ end of progn
    ) ;_ end of if
    (mapcar
        '(lambda (img) (setq all_raster_image_name (vl-remove img all_raster_image_name)))
        used_raster_image_name
    ) ;_ end of mapcar
  ;   (foreach item all_raster_image_name (command "_.-IMAGE" "_Detach" item))
    (mapcar 'DetachImage all_raster_image_name)
    (princ "\nНеиспользуемые растры ")
    (mapcar '(lambda (x) (princ x) (princ " ")) all_raster_image_name)
    (princ " ... удалены")
    (princ)
) ;_ end of defun
(defun C:XrefDet (/ all_xref used_xref)
    (vlax-for Blk (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
        (if (= (vla-get-isxref Blk) :vlax-true)
            (setq all_xref (cons blk all_xref))
        ) ;_ end of if
    ) ;_ end of vlax-for
    (if (setq xref_set (ssget "_X" '((0 . "INSERT"))))
        (progn
            (setq used_xref
                     (vl-remove-if-not
                         '(lambda (blk)
                              (vlax-property-available-p blk "path")
                          ) ;_ end of lambda
                         (mapcar 'vlax-ename->vla-object
                                 (vl-remove-if
                                     'listp
                                     (mapcar 'cadr (ssnamex xref_set))
                                 ) ;_ end of vl-remove-if
                         ) ;_ end of mapcar
                     ) ;_ end of vl-remove-if-not
            ) ;_ end of setq
        ) ;_ end of progn
    ) ;_ end of if
    (setq used_xref_name (mapcar 'vla-get-name used_xref))
    (mapcar
        '(lambda (xn)
             (setq all_xref (vl-remove-if '(lambda (x) (= (vla-get-name x) xn)) all_xref))
         ) ;_ end of lambda
        used_xref_name
    ) ;_ end of m
    (setq used_xref_name (mapcar 'vla-get-name all_xref))
    (vl-catch-all-apply
        '(lambda ()
             (mapcar 'vla-detach all_xref)
         ) ;_ end of lambda
    ) ;_ end of vl-catch-all-apply
    (princ "\nНеиспользуемые xerf ")
    (mapcar '(lambda (x) (princ x) (princ " ")) used_xref_name)
    (princ " ... удалены")
    (princ)
) ;_ end of defun
(princ "\nКоманды XrefDet и ImgDet загружены")