Можно ли редактировать 3dSolid через AutoLISP? (Страница 1 из 2)

когда-то где-то находил информацию как шируется эта билиберда - все довольно просто что-то типа обычного XOR но вот не могу найти и вспомнить какой ключ. может кто вспомнит?

А может отправить acisout
И отредактировать .sat файл.

(boole 6 x 95) для каждого элемента списка, полученного из строки посредством vl-string->list.

> vk
(17.06.2003 в 17:26:09)
И какую информацию получаем в результате?
Если можно небольшой пример.

Напомнить источник... Не помню, где видел, а вот что сам набросал, когда возникло желание вытянуть геометрию. Конечно, это совершенно черновой  вариант, над которым работать, да работать... Вывод непосредственно на экран, а там есть над чем подумать.

;; выбор объекта
(while (/= "3DSOLID" (cdr (assoc 0 (setq edat (entget (car (entsel))))))))
;; выделение данных 3DSOLID'а
(setq n (1- (length edat)))
(setq dat '())
(while (>= n 0)
  (if (= 1 (car (nth n edat)))
    (setq dat (cons (vl-string->list (cdr (nth n edat))) dat))
  ) ;_  if
  (setq n (1- n))
) ;_  while
(setq n (1- (length dat)))
(setq points '())
(setq plane-surfaces '())
(setq cone-surfaces '())
(setq straight-curves '())
(setq ellipse-curves '())
(while (>= n 0)
  (setq d (nth n (reverse dat)))
  (setq p '())
  (foreach x (reverse d) (setq p (cons (boole 6 x 95) p))) ; декодирование строки
  (setq str (vl-list->string p))
  ;; разбивка строкИ на отдельные стрОки
  (setq poss 0) ; начальная позиция
  (setq strl '()) ; список строк
  (while (setq pose (vl-string-search "\177" str poss))
    (setq strpart (substr str (1+ poss) (- pose poss)))
    (setq strl (cons (if (distof strpart)
                       (distof strpart)
                       strpart
                     ) ;_  if
                     strl
               ) ;_  cons
    ) ;_  setq
    (setq poss (1+ pose))
  )
  (setq strl (reverse strl)) ; список строк готов
  (princ "\n")
  (princ strl)
  ;; сортировка в списки-группы
  (cond
    ((= (car strl) "point") (setq points (cons (vl-remove "$-1" strl) points)))
    ((= (car strl) "plane-surface") (setq plane-surfaces (cons (vl-remove "$-1" strl) plane-surfaces)))
    ((= (car strl) "cone-surface") (setq cone-surfaces (cons (vl-remove "$-1" strl) cone-surfaces)))
    ((= (car strl) "straight-curve") (setq straight-curves (cons (vl-remove "$-1" strl) straight-curves)))
    ((= (car strl) "ellipse-curve") (setq ellipse-curves (cons (vl-remove "$-1" strl) ellipse-curves)))
  ) ;_  cond
  (setq n (1- n))
) ;_  while
(princ "\n")
(princ points)
(princ "\n")
(princ plane-surfaces)
(princ "\n")
(princ cone-surfaces)
(princ "\n")
(princ straight-curves)
(princ "\n")
(princ ellipse-curves)
(princ)

еще раз прошу прощения - торопливость не лучший партнер программиста... конечно-же vk был прав и лучше использовать vl-string->list:

(defun 3d-decode (lst)
  (if (/= (car lst) 1)
    lst
    (cons 1 (vl-list->string (mapcar '(lambda(x)(boole 6 x 95)) (vl-string->list (cdr lst)))))
  )
)

а третья функция вообще не нужна...
но у vk все проработано получше, особенно разбивка на строки и сортировки - я этого не делал по двум причинам
1. не было необходимой информации;
2. после того как увидел результат - интерес к структуре пропал, тем более что появились возможности ActiveX
тем не менее большое спасибо еще раз Vk!!!

> Сергей
Попадьин (18.06.2003 в 14:40:58)
У меня был интерес вытянуть из 3Dsolid (детали из листового материала) геометрию. Что касается прямоугольных деталей, там все достаточно просто, но как "выковырять" геометрию на сплайновых участках... не совсем понятно.
Через ActiveX не пробовал, может подскажете куда копать.
И еще заметил такой момент (это про точность): имеется точка (в вершине 3Dsolid'а) с координатой например X=1500. Так я ее задавал (), так она и отображается по команде ID. Но в строке после декодирования вижу что-то вроде 1499.999999999989.
Вторая строка содержит текущее время. Зачем???

Немного подправил программку. Теперь читается почти по-человечески.

(defun 3d_geom (/ edat n dat points plane-surfaces cone-surfaces straight-curves ellipse-curves d p s str poss strl pose strpart part)
  ;; выбор объекта
  (while (not (member (cdr (assoc 0 (setq edat (entget (car (entsel)))))) '("3DSOLID" "REGION" "BODY"))))
  ;; выделение данных 3DSOLID'а
  (setq n (1- (length edat)))
  (while (>= n 0)
    (if (= 1 (car (nth n edat)))
      (setq dat (cons (vl-string->list (cdr (nth n edat))) dat))
    ) ;_  if
    (setq n (1- n))
  ) ;_  while
  (setq n (1- (length dat)))
  (while (>= n 0)
    (setq d (nth n (reverse dat)))
    ;; декодирование строки
    (setq p '())
    (foreach x (reverse d)
      (if (< (setq s (boole 6 x 95)) 33)
        (setq s (+ s 64))
      ) ;_  if
      (setq p (cons s p))
    ) ;_  foreach
    (setq str (vl-list->string p))
    ;; разбивка строки на элементы
    (setq poss 0)                       ; начальная позиция
    (setq strl '())                     ; список элементов
    (while (setq pose (vl-string-search "\177" str poss))
      (setq strpart (substr str (1+ poss) (- pose poss)))
      (cond
        ((distof strpart)
         (setq part (atof strpart))
         (if (not (vl-string-search "." strpart))
           (setq part (atoi strpart))
         ) ;_  if
        )
        (t (setq part strpart))
      ) ;_  cond
      (setq strl (cons part strl))
      (setq poss (1+ pose))
    ) ;_  while
    (setq strl (reverse strl))          ; список элементов готов
    (princ "\n")
    (princ strl)
    ;; сортировка в списки-группы
    (cond
      ((= (car strl) "point") (setq points (cons (vl-remove "$-1" strl) points)))
; и так далее для других групп
    ) ;_  cond
    (setq n (1- n))
  ) ;_  while
  (princ "\n")
  (princ points)
; и так далее
  (princ)
) ;_  defun
(3d_geom)

Получается почти точная копия *.sat .
По поводу структуры *.sat догадываюсь, что ее описание найти проблематично, однако, есть одно предположение (не более): строки - это элементы и признаки элементов объекта, а параметры $ (за исключением $-1 - разделителя) являются связями между строками. Это определяет форму объекта. Но как к форме привязаны координаты - совсем не понятно.
Есть идеи?

вчера было немного свободного времени - посидел вечерком поковырял... разобраться вообщем-то пожалуй можно, по крайней мере шар, цилиндр и конус (оказывается описываются почти одинаково) научился модифицировать - правда, как работать с этими дебильными данными автоматизировано пока даже не могу себе представить... очень удивил ящичек - на его описание уходит более 120 (!!!) групп - там похоже есть и точки (все 8 нашел) и ребра (зачем то заданы точки средины) и грани и еще много чего не понятного... к сожалению объемы информации слишком велики для форума... дам лишь маленький совет
1. рисуйте по координатам (задавая циферками с клавы), а затем ищите в декодированном примитиве знакомые числа...
2. 3d-decode при повторном вызове даст закодированный вариант - это понадобится для entmod. А вызывать примерно так: (mapcar '3d-decode <декодированный список примитива>)

> Сергей Попадьин
Большое спасибо за ссылочку! Кое-что эта статья расставила по местам, но понятно одно, что механизм описания объекта в формате sat довольно сложный. Тоесть, редактировать, непосредственно само описание конечно можно, но не кажется ли, что в этом случае придется заново создать уже существующий механизм? Может быть, можно получить к нему доступ?
Что касается "точек середины" на ребрах и плоскостях, так здесь просто: заданы точка и вектор (для плоскости - нормаль) и действительно нет никакой разницы, в каком месте прямой или плоскости лежит точка. Может быть, это проекция центра тяжести на ребро\плоскость... проверю для более сложных тел...

Можно. Вот опять на него наткнулся http://xarch.tu-graz.ac.at/autocad/wiki/DecodeAcis

раньше описание SAT можно было взять прямо на сайте Spatial, сейчас жмотятся :(
но в инете его найти запросто, правда может старые версии
а их viewer (http://www.spatial.com/products/visuali … viewer.htm) также может помочь, например, там есть topology browser