• Bunfaot
  • Восстановленный участник
  • На форуме с 18 мая 2008г.
  • Сообщений: 2
  • Спасибо: 0

Тема: Работа с MS Word с помощью VBA. Нужна помощь.

В программировании не разбираюсь вообще... но препод гад дал всем задания.. и установил конечную дату. Как кто делать будет его не волнует. Вот поэтому обращаюсь к вам господа. Может ли кто помочь?
Задания следующие:
1. Работа с документами и текстом в MS Word с помощью VBA.
Задание. Операции: Добавление пустого абзаца, установка различных типов выравнивания абзаца, отступа первой строки, установка межстрочного ин-тервала.
2. Интегрирование приложений MS Office с помощью VBA.
Задание. Таблица имеет следующую структуру: код, название книги, автор, цена, кол-во листов
Хотел сделать в 1 задании к каждому пункту кнопку.
Получилось вот такое:

Private Sub CommandButton1_Click()
Selection.TypeText Text:="Работа с документами и текстом в MS Word с помощью VBA. Цель: Познакомится с наиболее часто используемыми объектами VBA, их свойствами и методами и научится работать с ними. Закрепить знания об использовании VBA при работе с документами в MS Word, составление программ с применением основных объектов и методов работы с текстом."
End Sub
Private Sub CommandButton2_Click()
Selection.ParagraphFormat.Alignment = wdAlignParagraphLeft
End Sub
Private Sub CommandButton3_Click()
Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
End Sub
Private Sub CommandButton4_Click()
Selection.ParagraphFormat.Alignment = wdAlignParagraphRight
End Sub
Private Sub CommandButton5_Click()
Selection.ParagraphFormat.Alignment = wdAlignParagraphJustify
End Sub
Private Sub CommandButton6_Click()
Selection.ParagraphFormat.LineSpacing = LinesToPoints(1.5)
End Sub
Private Sub CommandButton7_Click()
Selection.TypeText Text:=vbTab
End Sub
Private Sub CommandButton8_Click()
Selection.TypeParagraph
End Sub

Только как сделать так, чтобы все функции применялись к заданному тексту? А то, к примеру при нажатии на кнопку "по правому краю", перемещается не текст, а кнопка и т.д...
Во 2 задании нужна интеграция листа Excel в Word. С макросами не пойму как это сделать.
Как быть?

  • Fatty
  • Восстановленный участник
  • На форуме с 30 мая 2006г.
  • Сообщений: 989
  • Спасибо: 2

Re: Работа с MS Word с помощью VBA. Нужна помощь.

> Bunfaot
По первому вопросу посмотри здесь:
http://webfile.ru/1954264
~'J'~

  • Fatty
  • Восстановленный участник
  • На форуме с 30 мая 2006г.
  • Сообщений: 989
  • Спасибо: 2

Re: Работа с MS Word с помощью VBA. Нужна помощь.

> Bunfaot
Пример по второму вопросу:

Option Explicit
Sub CopyExcelTable()
'//' используется позднее связывание с приложением
'//' поэтому ссылка на библитеку MS Excel не нужна
    Dim xlApp As Object
    Dim xlBook As Object
    Dim xlSheet As Object
    Dim xlRange As Object
    Dim xlFileName As String
    '//' имя файла Эксель
    xlFileName = "С:\Темп\Пример.xls"
     '//' проверка на то что Эксель уже открыт
    If Tasks.Exists(Name:="Microsoft Excel") = False Then
         '//' если не открыт то создаем ссылку на объект Эксель
        Set xlApp = CreateObject("Excel.Application")
    ElseIf Tasks.Exists(Name:="Microsoft Excel") = True Then
         '//' если уже открыт получаем ссылку на него
        Set xlApp = GetObject(, "Excel.Application")
    Else
         '//' если Эксель не найден в системе генерируем сообщение
        MsgBox "Приложение Excel не найдено."
         '//' останавливаем процедуру
        End
    End If
     '//' делаем Эксель видимым
    xlApp.Application.Visible = True
     '//' открываем рабочую кникгу
    Set xlBook = xlApp.workbooks.Open(xlFileName)
    '//' получаем ссылку на нужный рабочий лист
    Set xlSheet = xlBook.WorkSheets("Sheet2")
    '//' активируем рабочий лист
    xlSheet.Activate
    '//' получаем ссылку на нужный диапазон
    Set xlRange = xlSheet.Range("A1:B10")
    '//' выделяем его (необязательное действие)
    xlRange.Select
    '//' копируем диапазон
    xlRange.Copy
    '//' вставляем таблицу Эксель в конец документа Word
    ThisDocument.Bookmarks("\endofdoc").Range.PasteExcelTable _
        LinkedToExcel:=True, _
        WordFormatting:=False, _
        RTF:=True
   '//' закрываем книгу,делаем уборку мусора
   Set xlRange = Nothing
   Set xlSheet = Nothing
   xlBook.Close
   Set xlRange = Nothing
   xlApp.Quit
   Set xlApp = Nothing
End Sub

~'J'~

  • Bunfaot
  • Восстановленный участник
  • На форуме с 18 мая 2008г.
  • Сообщений: 2
  • Спасибо: 0

Re: Работа с MS Word с помощью VBA. Нужна помощь.

> Fatty
wow... я уже не думал, что кто-нибудь поможет. Столько форумов уже облазил.
Завтра отнесу на проверку)))
Если что, с меня причитается)))