Есть ли на VB команда выбора цвета?

acedSetColorDialog

Private Declare Function acedSetColorDialog Lib "acad.exe" _
  (color As Long, ByVal bAllowMetaColor As Boolean, ByVal nCurLayerColor As Long) As Boolean
Sub ColorDlg()
Dim AllowMetaColor As Boolean, Res As Boolean
Dim DefColor As Long, NewColor As Long
   NewColor = 7
   bAllowMetaColor = True
   DefColor = 7
   Res = acedSetColorDialog(NewColor, AllowMetaColor, DefColor)
End Sub

acedSetColorDialogTrueColor

Private Declare Function CHOOSECOLOR Lib "comdlg32.dll" Alias "ChooseColorA" (pChoosecolor As CHOOSECOLOR) As Long

AnyObj.Color = cc.rgbResult

Private Declare Function acedSetColorDialog Lib "acad.exe" _
  (Color As acColor, ByVal AllowMetaColor As Byte) As Byte
'   Color - передаёт значение по умолчанию и принимает новое;
'   AllowMetaColor - определяет активность кнопок ByLayer и ByBlock:
'                            0 - не активны;
'                            1 - активны.
Sub DlgColorACI()
Dim Color As acColor, ColorOld As acColor
Dim AllowMetaColor As Byte, Result As Byte
   Color = acByLayer
   AllowMetaColor = 1
   On Error Resume Next
   ColorOld = Color
   Result = acedSetColorDialog(Color, AllowMetaColor)
   On Error GoTo 0
   If Color = ColorOld Then
      MsgBox "Выбор был отменён!", vbExclamation
    Else
      MsgBox "Вы выбрали: " & Color & " цвет!", vbInformation
   End If
End Sub

Private Declare Function DoColorDialog Lib "color.dll" _
  (ByVal NotUsed As Long, ByVal ColorCurrent As acColor, ByVal NotUsed As Long, _
  ByVal NotUsed As Long, ByVal AllowMetaColor As Byte) As acColor
'   ColorCurrent - передаёт значение по умолчанию;
'   AllowMetaColor - определяет активность кнопок ByLayer и ByBlock:
'                            0 - не активны;
'                            1 - активны.
'   Возвращает:
'              -1 - при отмене выбора;
'              0-256 - выбранный цвет.
Sub DlgColorACI()
Dim Color As acColor, ColorCurrent As acColor
Dim AllowMetaColor As Byte
   ColorCurrent = 125
   AllowMetaColor = 1
   Color = DoColorDialog(0, ColorCurrent, 0, 0, AllowMetaColor)
   If Color = -1 Then
      MsgBox "Выбор был отменён!", vbExclamation
    Else
      MsgBox "Вы выбрали: " & Color & " цвет!", vbInformation
   End If
End Sub

Type tColor
   NotKnow As Long
   Color As Long
   ColorName As Long
   ColorBook As Long
End Type
Private Declare Function acedSetColorDialogTrueColor Lib "acad.exe" _
  (Color As tColor, ByVal AllowMetaColor As Byte, _
   ColorCurrent As tColor, ByVal ColorSystems As Byte) As Byte
'   Color - передаёт значение по умолчанию и принимает новое;
'   AllowMetaColor - определяет активность кнопок ByLayer и ByBlock:
'                       0 - не активны;
'                       1 - активны;
'   ColorCurrent - не используется, но обязано быть определено, возможно было
'                  задекларировано на будущее, для передачи цвета по умолчанию;
'   ColorSystems - определяет набор отображаемых вкладок с цветавыми системами:
'                     1 - ACI;
'                     2 - RGB;
'                     4 - BookName;
'                  Сумма данных значений даёт требуемый набор:
'                     1+2=3   - ACI+RGB;
'                     1+4=5   - ACI+BookName;
'                     2+4=6   - RGB+BookName;
'                     1+2+4=7 - ACI+RGB+BookName.
'
Sub DlgTrueColor()
Dim Color As AcadAcCmColor
Dim AllowMetaColor As Byte, ColorSystems As Byte, Result As Byte
Dim ColorOld As Long
Dim ColorLong As tColor, ColorCurrent As tColor ' При переносе данной строки из конца в другое место и выборе именованого цвета AutoCAD вылетает.
   With ColorLong
      .NotKnow = 1691390208 ' В необходимости данного параметра разобраться не смог, видимо какой-то адресс, поэтому просто передаём данное значение.
      .Color = -1024366560  ' Значение цвета по умолчанию в формате AcCmEntityColor или AcadEntityObj.TrueColor.EntityColor
      .ColorName = 0        ' Адрес по каторому располагается имя цвета.
      .ColorBook = 0        ' Адрес по которому располагается имя библиотеки цвета.
   End With
   With ColorCurrent
      .NotKnow = 1691390208
      .Color = -1023410169
      .ColorName = 0
      .ColorBook = 0
   End With
   AllowMetaColor = 1
   ColorSystems = 7
   On Error Resume Next
   ColorOld = ColorLong.Color
   Result = acedSetColorDialogTrueColor(ColorLong, AllowMetaColor, ColorCurrent, ColorSystems)
   On Error GoTo 0
   If ColorLong.Color = ColorOld Then
      MsgBox "Выбор был отменён!", vbExclamation
    Else
      Set Color = Application.GetInterfaceObject("AutoCAD.AcCmColor.16")
      Color.EntityColor = ColorLong.Color
      If Color.ColorMethod = acColorMethodByRGB Then
         MsgBox "Вы выбрали: " & Chr(13) & Chr(10) & _
           "   цветовая система: RGB - " & Color.ColorMethod & Chr(13) & Chr(10) & _
           "   цвет: R" & Color.Red & ":G" & Color.Green & ":B" & Color.Blue, vbInformation
       Else
         MsgBox "Вы выбрали: " & Chr(13) & Chr(10) & _
           "   цветовая система: ACI - " & Color.ColorMethod & Chr(13) & Chr(10) & _
           "   цвет: " & Color.ColorIndex, vbInformation
      End If
   End If
End Sub

Sub HexToColor()
Dim ColorMethod As Byte, ColorIndex As Byte
Dim Red As Byte, Green As Byte, Blue As Byte
Dim ColorHex As String
   ColorHex = "C2F16820"
   ColorMethod = Val("&H" & Left(ColorHex, 2))
   Select Case ColorMethod
    Case 192: ColorIndex = 256               ' ByLayer
    Case 193: ColorIndex = 0                 ' ByBlock
    Case 194                                 ' ByRGB
      Red = Val("&H" & Mid(ColorHex, 3, 2))
      Green = Val("&H" & Mid(ColorHex, 5, 2))
      Blue = Val("&H" & Right(ColorHex, 2))
    Case 195                                 ' ByACI
      ColorIndex = Val("&H" & Right(ColorHex, 2))
    Case 197                                 ' Foreground
   End Select
End Sub

Sub EntityColorToColor()
Dim ColorMethod As Byte, ColorIndex As acColor
Dim Red As Byte, Green As Byte, Blue As Byte
Dim ColorLong As Long
   ColorLong = -1024366560
   ColorMethod = (ColorLong And &H7F000000) \ &H1000000
   If ColorLong < 0 Then ColorMethod = ColorMethod Or &H80
   Select Case ColorMethod
    Case acColorMethodByLayer: ColorIndex = 256
    Case acColorMethodByBlock: ColorIndex = 0
    Case acColorMethodByRGB
      Red = (ColorLong And &HFF0000) \ &H10000
      Green = (ColorLong And &HFF00&) \ &H100&
      Blue = ColorLong And &HFF&
    Case acColorMethodByACI
      ColorIndex = ColorLong And &HFF&
    Case acColorMethodForeground
   End Select
End Sub

Sub ColorToHex()
Dim ColorMethod As AcColorMethod
Dim ColorIndex As acColor
Dim Red As Byte, Green As Byte, Blue As Byte
Dim EntityColor As Long
Dim ColorHex As String
   ColorMethod = acColorMethodByRGB
   If ColorMethod = acColorMethodByRGB Then
      Red = 241
      Green = 104
      Blue = 32
      ColorHex = Hex(ColorMethod) & Hex(Red) & Hex(Green) & Hex(Blue)
    ElseIf ColorMethod = acColorMethodByACI Then
      ColorIndex = acYellow
      ColorHex = Hex(ColorMethod) & "0000" & Hex(ColorIndex)
    Else
      ColorHex = Hex(ColorMethod) & "000000"
   End If
   EntityColor = Val("&H" & ColorHex)
End Sub