Как работать с электронной таблицей Excel?

Option Explicit
Option Base 0
Option Compare Text
Sub nameBlock()
Dim Excel, curSheet, curBook As Object
Dim objSelSet As AcadSelectionSet
Dim objBlock As AcadBlock
Dim intType(0) As Integer
Dim varData(0) As Variant
Dim nameObjSelSet, progBook As String
Dim i As Long
nameObjSelSet = "temp"
'Это имя Excel-евского файла, в котором находятся
'необходимые процедуры для дальнейшей обработки
progBook = "C:\Макросы\Мои_Программы.xls"
For Each objSelSet In ThisDrawing.SelectionSets
    If objSelSet.name = nameObjSelSet Then
        ThisDrawing.SelectionSets.Item(nameObjSelSet).Delete
        Exit For
    End If
Next
Set objSelSet = ThisDrawing.SelectionSets.Add(nameObjSelSet)
intType(0) = 0
varData(0) = "INSERT"
objSelSet.Select acSelectionSetAll, filtertype:=intType, filterdata:=varData
If objSelSet.Count = 0 Then
    GoTo Exit_Here
End If
On Error Resume Next
Err.Clear
Set Excel = GetObject(, "Excel.Application")
If Err.Number > 0 Then
    Set Excel = CreateObject("Excel.Application")
End If
On Error GoTo Exit_Here
With Excel
    .SheetsInNewWorkbook = 1
    .DisplayAlerts = False
    .Visible = False
    .WindowState = acMin
End With
'Открываем "программный" файл, дабы все было
'в боевой готовности
Excel.Workbooks.Open fileName:=progBook
'Добавляем книгу, в которой, собственно, и будем работать.
Set curBook = Excel.Workbooks.Add
Set curSheet = curBook.Sheets(1)
curSheet.name = "Количество блоков"
For i = 0 To objSelSet.Count - 1
    curSheet.Cells(i + 1, 1).Value = objSelSet.Item(i).name
Next
AutoCAD.WindowState = acMin
With Excel
    .Visible = True
    .WindowState = acMax
    .DisplayAlerts = True
'А теперь запускается родной Excel-евский макрос, который и
'делает все, что положено:
'подсчитывает записи, вводит формулы, форматирует ячейки и
'т. п. Cамо собою в книге
'[i]Мои_Программы.xls[/i] должна быть процедура
'[i]Форматирование[/i].
    .Run "Мои_Программы.xls!Форматирование"
End With
Exit_Here:
Set Excel = Nothing
Set curSheet = Nothing
Set curBook = Nothing
Set objSelSet = Nothing
Set objBlock = Nothing
End Sub