Компонент Delphi для просмотра DWG

procedure TFormBrowser.QuickView(filename: string);
// Процедура предпросмотра любого файла
var
  Ext: string;
  vs: string;
// Процедура просмотра ThumbNail. Весь секрет в ней!
  procedure setImgAsThumb;
    var
      s: TFileStream;
      clrData: pointer;
      hdrStart,
      hdrSz,
      bmpStart,
      bmpSz,
      wmfStart,
      wmfSz,
      hgt,
      wdt,
      ipos: dword;
      i: cardinal;
      sentV: array[1..16] of byte;
      mHead: packed record
        allSz : dword;
        imgCnt: byte;
      end;
      dHead: packed record
        code  : byte;
        dStart: dword;
        dSize : dword;
      end;
      intBmpHdr: BITMAPINFOHEADER;
      intBmp   : HBITMAP;
      intBmpInf: ^BITMAPINFO;
      dc       : HDC;
    const
      sent: array[1..16] of
byte=($1F,$25,$6D,$07,$D4,$36,$28,$28,
      $9D,$57,$CA,$3F,$9D,$44,$10,$2B
     );
  begin
    hdrStart:=0;
    hdrSz:=0;
    bmpStart:=0;
    bmpSz:=0;
    wmfStart:=0;
    wmfSz:=0;
    hgt:=0;
    wdt:=0;
    if AcadVer(filename, vs)>12
      then begin
// Открыли файл для чтения
        s:=TFileStream.Create(filename, fmOpenRead);
        s.Seek($0D, 0);
        s.Read(ipos, sizeof(ipos));
        s.Seek(ipos, 0);
        s.Read(sentV[1], 16);
        if CompareMem(@sentV, @sent, 16)
          then begin
            s.Read(mHead, sizeof(mHead));
            for i:=1 to mHead.imgCnt do begin
              s.Read(dHead, sizeof(dHead));
              case dHead.code of
                1 : begin
                      hdrStart:=dHead.dStart;
                      hdrSz:=dHead.dSize;
                    end;
                2 : begin
                      bmpStart:=dHead.dStart;
                      bmpSz:=dHead.dSize;
                    end;
                3 : begin
                      wmfStart:=dHead.dStart;
                      wmfSz:=dHead.dSize;
                    end;
              end;//case
            end;
            if (bmpStart<>0) and (bmpSz<>0)
              then begin
// Разыскали картинку
                s.Seek(bmpStart, 0);
                s.Read(intBmpHdr, sizeof(intBmpHdr));
                if intBmpHdr.biSizeImage>0
                  then begin
                    GetMem(intBmpInf,
                            (sizeof(BITMAPINFOHEADER)+
                              (intBmpHdr.biClrUsed*4)
                            )
                           );
                    intBmpInf^.bmiHeader:=intBmpHdr;
                    s.Read(intBmpInf^.bmiColors,
                                   (intBmpHdr.biClrUsed*4)
                          );
                    GetMem(clrData, intBmpHdr.biSizeImage);
                    s.Read(clrData^, intBmpHdr.biSizeImage);
                    dc:=CreateDC('DISPLAY', nil, nil, nil);
// Прочитали
                    intBmp:=CreateDIBitmap(dc,
                                           intBmpHdr,
                                           CBM_INIT,
                                           clrData,
                                           intBmpInf^,
                                           DIB_RGB_COLORS);
                    if intBmp<>0
                      then begin
// И нарисовали на форме
                        viewImage.Picture.Bitmap.Handle:=intBmp;
                        viewImage.Show;
                        viewScrollBoxImg.Show;
                      end;
                    FreeMem(intBmpInf);
                    FreeMem(clrData);
                    DeleteDC(dc);
                  end;
              end;
          end;
        s.Free;
      end;
  end;
// Основная процедура предпросмотра
begin
  if not (FileExists(filename))
    then begin
// Выводим вместо картинки сообщение "Просмотр невоможен"
      NoView;
      Exit;
    end;
  if AnsiCompareFileName(filename, FCurrentViewF)=0
    then exit;
  FCurrentViewF:=filename;
  viewScrollBoxImg.Visible:=false;
  viewText.Visible:=False;
  bShowDWF.Hide;
  if not cbQViewEnable.Checked
    then begin
      NoView;
      Exit;
    end;
  Ext:=copy(ExtractFileExt(filename), 2, length(filename));
  Ext:=AnsiUpperCase(Ext);
  if FTxtExts.IndexOf(Ext)>=0
    then begin
      viewText.Visible:=True;
      panView.Alignment:=taLeftJustify;
      viewText.FileName:=Filename;
      viewText.IsOpen:=true;
      if not viewText.IsOpen
        then NoView;
    end
// Просмотр DWG-файла
  else if Ext = 'DWG'
    then begin//dwg
      vs:='Рисунок Автокад';
// Просмотр картинки
      setImgAsThumb;
      panView.Caption:=vs;
      Ext:=ExistsDWFforDWG(filename);
      bShowDWF.Visible:=Ext<>'';
      FDWFFile:=Ext;
      panView.Alignment:=taCenter;
      Screen.Cursor:=crDefault;
    end //ext=dwg
// Просмотр обычных картинок
  else if ((Ext = 'BMP')
        or (Ext = 'ICO')
        or (Ext = 'WMF')
        or (Ext = 'JPG')
        or (Ext = 'JPEG')
        or (Ext = 'GIF')
        )
    then begin
      viewText.Visible:=False;
      bShowDWF.Hide;
      viewScrollBoxImg.Visible:=false;
      panView.Caption:='';
      panView.Alignment:=taLeftJustify;
      try
        Screen.Cursor:=crHourGlass;
        viewImage.Picture.LoadFromFile(Filename);
        viewScrollBoxImg.Visible:=true;
      except
        NoView;
      end;
      Screen.Cursor:=crDefault;
    end
    else if (Ext='DWF')
    then begin
      try
        FDWFFile:=Filename;
        bShowDWF.Show;
        panView.Caption:='';
      except
        NoView;
      end;
    end
    else NoView;
end;