Как перевести в спецификацию количество одинаковых блоков с чертежа автоматом?

bom.lsp:
 ;Copyright 2000 EMT Software, Inc.
 ;
(defun C:BOMM (/ #SSET #ENT #LST #IPT #SPT #UL #DX #DY #LS #CS
                #CNT #NUM #DATA-M #TXT #TBOX-M #PT-LST #PTS1 #PTS2
                #TMP #TMP-M #TMP-S #TMP-C #X #XA #XX dcl_id #STAT @MAINDIALOG)
  (defun @MAINDIALOG  (/ @DIALOG)
    (defun @DIALOG  ()
      (if (not (new_dialog "blk_tbl" dcl_id)) (quit))
      (set_tile "lnsp" (rtos #LS))
      (set_tile "clsp" (rtos #CS))
      (action_tile "lnsp" "(setq #LS (atof $value))")
      (action_tile "clsp" "(setq #CS (atof $value))")
      (start_dialog))
    (setq dcl_id (load_dialog "bom"))
    (if dcl_id
      (@DIALOG)
      (alert "Unable to load Bom dialog.")))
  (setq #LS   (getvar "textsize")
        #CS   (getvar "textsize"))
  (setq #STAT (@MAINDIALOG))
  (if (> #STAT 0)
    (progn
      ; create a list of attributes - < << Tag . Value > < Tag . Value >> >
      (setq #SSET (ssget (list (cons 0 "INSERT")))
            #CNT  0)
      (if (not #SSET)
        (setq #NUM 0)
        (setq #NUM (sslength #SSET)))
      (while (/= #CNT #NUM)
        (setq #ENT (entnext (ssname #SSET #CNT))
              #TMP nil)
        (if #ENT
          (if (= (cdr (assoc 0 (setq #ENT (entget #ENT)))) "ATTRIB")
            (while (/= (cdr (assoc 0 #ENT)) "SEQEND")
              (if (= (cdr (assoc 0 #ENT)) "ATTRIB")
                (setq #TMP (append #TMP
                                   (list (cons (cdr (assoc 2 #ENT))
                                               (cdr (assoc 1 #ENT)))))))
              (setq #ENT (entget (entnext (cdr (assoc -1 #ENT))))))))
        (if #TMP
          (setq #LST (append #LST (list #TMP))))
        (setq #CNT (1+ #CNT)))
      (if #LST
        (progn
          ; count the blocks and add to the list
          (setq #TMP-S '()
                #TMP-C '())
          (foreach #X #LST
            (if (not (member #X #TMP-S))
              (progn
                (setq #CNT   0
                      #TMP   #LST
                      #TMP-M #TMP)
                (while #TMP-M
                  (if (member #X #TMP-M)
                    (setq #CNT (1+ #CNT)))
                  (setq #TMP-M (cdr (member #X #TMP-M))))
                (if (> #CNT 0)
                  (setq #TMP-S (append #TMP-S (list #X))
                        #TMP-C (append #TMP-C (list (append (list (cons "К-во" (itoa #CNT))) #X))))))))
          (setq #LST #TMP-C)
          ; sort list into columns
          (setq #DATA-M '())
          ; setup 1st element and column list
          (foreach #X (car #LST)
            (setq #DATA-M (append #DATA-M (list (list (car #X) (cdr #X))))))
          (setq #LST (cdr #LST))
          (foreach #X #LST
            ; add any new columns to #DATA-M
            (foreach #XA #X
              (if (not (assoc (car #XA) #DATA-M))
                (progn
                  (setq #TMP (list (car #XA))
                        #CNT (length (car #DATA-M)))
                  (repeat (- #CNT 1)
                    (setq #TMP (append #TMP (list ""))))
                  (setq #DATA-M (append #DATA-M (list #TMP))))))
            ; process through the list of columns started above
            (foreach #XX #DATA-M
              (if (assoc (car #XX) #X)
                (setq #DATA-M (subst (append (assoc (car #XX) #DATA-M)
                                             ; add just the value to list
                                             (list (cdr (assoc (car #XX) #X))))
                                     (assoc (car #XX) #DATA-M)
                                     #DATA-M))
                (setq #DATA-M (subst (append (assoc (car #XX) #DATA-M)
                                             ; add null place setting to list
                                             (list ""))
                                     (assoc (car #XX) #DATA-M)
                                     #DATA-M)))))
          ; find the longest string in each column.
          (setq #CNT '()  #TBOX-M '())
          (foreach #X #DATA-M
            ; max. number of chr in column.
            (setq #CNT (strlen (car #X)))
            (foreach #XX #X
              (setq #NUM (strlen #XX)
                    #CNT (max #CNT #NUM)))
            ; convert to <textbox> coordinates.
            (setq #TXT "")
            (repeat (+ #CNT 4)
              (setq #TXT (strcat #TXT "X")))
            (setq #TBOX-M (cadr (textbox (list (cons 1 #TXT)))))
            ; store it with the column lists.
            (setq #TMP-M  (car #DATA-M)
                  #DATA-M (cdr #DATA-M))
            (setq #TMP-M  (append (list #TBOX-M) #TMP-M)
                  #DATA-M (append #DATA-M (list #TMP-M))))
          ; create table.
          (setq #UL  (getpoint "\nPick Upper Left corner for the Table: ")
                #SPT (list (+ (car #UL) #CS) (- (cadr #UL) #LS) 0.0)
                #TMP-M '())
          ; each member in #DATA-M = < textbox point, list of strings... >
          (foreach #X #DATA-M
            (setq #TMP (car #X)
                  #X   (cdr #X)
                  #DX  (car #TMP)
                  #DY  (cadr #TMP)
                  #IPT (list (car #SPT) (- (cadr #SPT) #DY) 0.0)
                  #SPT (list (+ (car #SPT) (+ #DX #CS)) (cadr #SPT) 0.0)
                  #PT-LST '())
            (foreach #XX #X
              (entmake (list (cons 0 "TEXT") (cons 10 #IPT) (cons 40 #DY) (cons 1 #XX)))
              (setq #PT-LST (append #PT-LST (list #IPT))
                    #IPT (list (car #IPT) (- (cadr #IPT) (+ #DY (* #LS 2.0))) 0.0)))
            ; a list of lists of insert points for horz. lines later.
            (setq #TMP-M (append #TMP-M (list #PT-LST)))
            ; vert. line between columns.
            (entmake (list (cons 0 "LINE")
                           (cons 10 (list (- (car #SPT) #CS) (cadr #UL) 0.0))
                           (cons 11 (list (- (car #SPT) #CS) (+ (cadr #IPT) (+ #DY #LS)) 0.0)))))
          ; get the start points and end points for horz. lines.
          (setq #PTS1 (car #TMP-M)
                #PTS2 (last #TMP-M))
          (foreach #X #PTS1
            (if #PTS2
              (entmake (list (cons 0 "LINE")
                             (cons 10 (list (- (car #X) #CS) (- (cadr #X) #LS) 0.0))
                             (cons 11 (list (+ (caar #PTS2) #DX) (- (cadar #PTS2) #LS) 0.0)))))
            (setq #PTS2 (cdr #PTS2)))
          ; draw top and left lines.
          (setq #IPT (list (+ (car #IPT) (+ #DX #CS)) (cadr #IPT) 0.0))
          (entmake (list (cons 0 "LINE")
                         (cons 10 #UL)
                         (cons 11 (list (car #UL) (+ (cadr #IPT) (+ #DY #LS)) 0.0))))
          (entmake (list (cons 0 "LINE")
                         (cons 10 #UL)
                         (cons 11 (list (- (car #IPT) #CS) (cadr #UL) 0.0))))))))
  (if dcl_id (unload_dialog dcl_id))
  (princ))
;;; Uncomment for the language needed.
;(princ "\n\nBOM?р?ь?Н???Д?J?n")  ; For Japanese.
(princ "\n\nType BOM to start.") ; For English.
(princ)
bom.dcl :
blk_tbl : dialog {
   label = "Table Settings";
   : column {
      : edit_box {
         edit_width = 20;
         key = "lnsp";
         label = "Line Spacing:";
      }
      : edit_box {
         edit_width = 20;
         key = "clsp";
         label = "Column Spacing:";
      }
   }
   ok_cancel;
}